[AYUDA] problemas con file-status

[Marengo97]

Hola, estoy escribiendo un programa que contiene un registro de libros para agregar, quitar, buscar, etc.. todo iba bien hasta que escribi la seccion de file status para que el programa
pueda saber si es necesario crear un archivo en caso que este no existe, se que puedo hacer funcionar el programa sin hacer esto pero como una buena practica quiero aprender a usar los file status.
El problema en cuestion esta al ingresar en la opcion 3,en el parrafo VER-LIBROS coloque un if para determinar si F-NOEXISTE-REG es TRUE disparar un mensaje de error, y en caso que no,que proceda a leer el archivo y mostrar todo lo que contiene, si elimino el archivo y presiono 3 me muestra ese error a la perfeccion pero si creo el archivo o el archivo ya existe de antemano luego no ingresa a la seccion 3, o simplemente se saltea el if o simplemente no me muestra ningun libro a pesar de haber ingresado algunos.
Aqui dejo mi codigo, cualquier ayuda, consejo, cosa que mejorar se agradece..
IDENTIFICATION DIVISION.

PROGRAM-ID. LIBRERIA.
AUTHOR. LUCAS GALEANO.
DATE-WRITTEN 9/7/2023.

ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT REG-LIBROS ASSIGN TO "REGISTRO-LIBROS.DAT"
ORGANIZATION IS INDEXED
RECORD KEY IS LIBRO-ID
ACCESS MODE IS DYNAMIC
file status FS-REGISTRO-LIBROS.

DATA DIVISION.
FILE SECTION.

FD REG-LIBROS.

01 DATOS-LIBRO.
05 LIBRO-ID PIC 999 VALUE ZEROS.
05 NOMBRE PIC X(20) VALUE SPACES.
05 EDITORIAL PIC X(20) VALUE SPACES.
05 ESTADO PIC X(12) VALUE SPACES.
*05 FECHA-INGRESO.
* 10 DIA PIC 99 VALUE ZEROS.
* 10 MES PIC X(10) VALUE SPACES.
* 10 AÑO PIC 9999 VALUE ZEROS.
* 05 FECHA-ALQUILER.
* 10 DDIA PIC 99 VALUE ZEROS.
* 10 MMES PIC X(10) VALUE SPACES.
* 10 AAÑO PIC 9999 VALUE ZEROS.

WORKING-STORAGE SECTION.
*Codigos de error del archivo.
01 FS-REGISTRO-LIBROS PIC XX.
88 ESTA-REG VALUE "00" "02".
88 N-ESTA-REG VALUE "23".
88 F-NOEXISTE-REG VALUE "35".
*Variables del programa.
77 CONTINUAR PIC X.
77 CONTINUAR-REG PIC X.
77 OPC PIC X VALUE SPACES.
77 LIMPIAR PIC X(80) VALUE SPACES.
77 N PIC 99.

PROCEDURE DIVISION.
DECLARATIVES.
FILE-ERROR SECTION.
USE AFTER STANDARD ERROR PROCEDURE ON REG-LIBROS.
IF FS-REGISTRO-LIBROS EQUALS "35" THEN
SET F-NOEXISTE-REG TO TRUE
END-IF.
END DECLARATIVES.
MENU.

PERFORM UNTIL CONTINUAR = "N"
PERFORM LIMPIAR-PANTALLA
DISPLAY "ADMINISTRADOR DE CATALOGO" AT LINE 1 COL 1 WITH
REVERSE-VIDEO
DISPLAY " " AT LINE 3 COL 1
DISPLAY "1.Registrar libro" AT LINE 4 COL 1
DISPLAY "2.Eliminar libro" AT LINE 5 COL 1
DISPLAY "3.Ver catalogo" AT LINE 6 COL 1
DISPLAY "4.Crear nuevo registro" AT LINE 7 COL 1
DISPLAY "0.Salir" AT LINE 8 COL 1
DISPLAY " " AT LINE 9 COL 1
DISPLAY "Ingrese tecla ( )" AT LINE 10 COL 1 WITH
REVERSE-VIDEO
ACCEPT OPC AT LINE 10 COL 16 WITH
PROMPT UNDERLINE
EVALUATE OPC
WHEN 1 PERFORM REGISTRAR-LIBRO
* WHEN 2 PERFORM ELIMINAR-LIBRO
WHEN 3 PERFORM VER-LIBROS
WHEN 4 PERFORM CREAR-ARCHIVO
WHEN 0 MOVE "N" TO CONTINUAR
END-EVALUATE
END-PERFORM.
CLOSE REG-LIBROS.
STOP RUN.


REGISTRAR-LIBRO.
MOVE "S" TO CONTINUAR-REG.
INITIALIZE DATOS-LIBRO.
PERFORM LIMPIAR-PANTALLA.
*INTERFAZ MENU DE INGRESO DE DATOS
DISPLAY "Numero de serie:" AT LINE 1 COL 1.
DISPLAY "Nombre:" AT LINE 2 COL 1.
DISPLAY "Editorial:" AT LINE 3 COL 1.
DISPLAY "Estado:" AT LINE 4 COL 1.
DISPLAY
"presione enter sin ingresar datos para salir al menu"
AT LINE 7 COL 12
WITH REVERSE-VIDEO.


DISPLAY "Numero de serie :" AT LINE 1 COL 1 WITH
REVERSE-VIDEO.
ACCEPT LIBRO-ID WITH PROMPT UNDERLINE UPDATE AT LINE 1 COL 25.

IF LIBRO-ID EQUALS 000 MOVE "N" TO CONTINUAR-REG
END-IF.

IF CONTINUAR-REG EQUALS "S"
DISPLAY "Numero de serie :" AT LINE 1 COL 1
DISPLAY LIBRO-ID AT LINE 1 COL 25

DISPLAY "Nombre :" AT LINE 2 COL 1 WITH REVERSE-VIDEO
ACCEPT NOMBRE AT LINE 2 COL 25
DISPLAY "Nombre: " AT LINE 2 COL 1
DISPLAY NOMBRE AT LINE 2 COL 25

DISPLAY "Editorial :" AT LINE 3 COL 1 WITH REVERSE-VIDEO
ACCEPT EDITORIAL AT LINE 3 COL 25
DISPLAY "Editorial :" AT LINE 3 COL 1
DISPLAY EDITORIAL AT LINE 3 COL 25

DISPLAY "Estado :" AT LINE 4 COL 1 WITH REVERSE-VIDEO
ACCEPT ESTADO AT LINE 4 COL 25
DISPLAY "Estado :" AT LINE 4 COL 1
DISPLAY ESTADO AT LINE 4 COL 25


PERFORM ABRIR-IO-ARCHIVO
WRITE DATOS-LIBRO INVALID KEY
REWRITE DATOS-LIBRO INVALID KEY
DISPLAY "ERROR AL REGISTRAR DATOS"
END-WRITE
PERFORM CERRAR-ARCHIVO
END-IF.

VER-LIBROS.
PERFORM LIMPIAR-PANTALLA
PERFORM ABRIR-IO-ARCHIVO
IF F-NOEXISTE-REG THEN
PERFORM LIMPIAR-PANTALLA
DISPLAY "ERROR, NO EXISTE UN ARCHIVO DE REGISTROS" AT LINE 1
COL 1

DISPLAY "PRESIONE ENTER PARA VOLVER AL MENU()" AT LINE 10
COL 1
ACCEPT OPC AT LINE 11 COL 36
ELSE
PERFORM LIMPIAR-PANTALLA
READ REG-LIBROS KEY IS LIBRO-ID
AT END MOVE HIGH-VALUE TO DATOS-LIBRO
PERFORM VARYING N FROM 1 BY 1 UNTIL DATOS-LIBRO = HIGH-VALUE
DISPLAY DATOS-LIBRO AT LINE N COL 1
READ REG-LIBROS KEY IS LIBRO-ID
AT END MOVE HIGH-VALUE TO DATOS-LIBRO
END-PERFORM
ADD 1 TO N
DISPLAY "PRESIONE ENTER PARA REGRESAR AL MENU" AT LINE N
COL 1
ACCEPT OPC AT LINE 15
PERFORM CERRAR-ARCHIVO
END-IF.





LIMPIAR-PANTALLA.
PERFORM VARYING N FROM 1 BY 1 UNTIL N>24
DISPLAY LIMPIAR AT LINE N COLUMN 1
END-PERFORM.

CREAR-ARCHIVO.
OPEN OUTPUT REG-LIBROS.

CERRAR-ARCHIVO.
CLOSE REG-LIBROS.

ABRIR-IO-ARCHIVO.
OPEN I-O REG-LIBROS.

[JCantero]

@Marengo97, eso es porque lees el registro con el valor de "LIBRO-ID" no existe y se sale.

Te adjunto código para leer todos de una mejor forma.

Modifica esta variable añadiendo un nuevo file status.


*Codigos de error del archivo.
01 FS-REGISTRO-LIBROS PIC XX.
88 ESTA-REG VALUE "00" "02".
88 N-ESTA-REG VALUE "23".
88 F-NOEXISTE-REG VALUE "35".
88 fin-reg value "10".


Y recorre el fichero de esta forma:


VER-LIBROS.
PERFORM LIMPIAR-PANTALLA
PERFORM ABRIR-IO-ARCHIVO
IF F-NOEXISTE-REG THEN
PERFORM LIMPIAR-PANTALLA
DISPLAY "ERROR, NO EXISTE UN ARCHIVO DE REGISTROS" AT LINE 1
COL 1

DISPLAY "PRESIONE ENTER PARA VOLVER AL MENU()" AT LINE 10
COL 1
ACCEPT OPC AT LINE 11 COL 36
ELSE
PERFORM LIMPIAR-PANTALLA

initialize libro-id
start reg-libros key is >= libro-id end-start
READ REG-LIBROS next record end-read

PERFORM VARYING N FROM 1 BY 1 UNTIL fin-reg
DISPLAY DATOS-LIBRO AT LINE N COL 1
READ REG-LIBROS next record end-read
END-PERFORM
ADD 1 TO N
DISPLAY "PRESIONE ENTER PARA REGRESAR AL MENU" AT LINE N
COL 1
ACCEPT OPC AT LINE 15
PERFORM CERRAR-ARCHIVO
END-IF.



si tienes alguna duda hazmelo saber.

[Marengo97]

Funciona perfecto!
Podria explicarme como es que funciona?
Antes de aplicar el file status era bastante simple pero al parecer cambia el codigo de ver-libros al usarlo, entiendo los statement de initialize y start, no tanto el de next record, pero no entiendo la logica que aplicó, por ende no se por que funciona.
El uuunico error que encontre es que si creo el archivo, de no existir, entra en un loop infinito mostrando "000" al entrar a la opcion 3, pero al cerrar el programa y volver a ejecturlo funciona perfecto y muestra el registro vacio, como podria solucionarlo? Gracias.

[Marengo97]

Ya lo solucione, resulta que cuando creaba el archivo no lo cerraba luego de abrirlo y al ingresar en la opcion 3 yo indico que abre en modo I-O y eso rompia el programa, pero aun no entiendo su codigo en totalidad jaja.

[JCantero]

@Marengo97, te explico.

Tu has hecho un bucle y siempre lees el mismo registro con el contenido de la clave "libro-id". No cambias libro-id. Otra cosa es que cambiaras el valor aumentandolo, pero realmente tendrias lecturas fallidas.

Cuando quieres recorrer un fichero completamente:

1) realiza un start con la clave deseada, para poner el cursor de lectura al principio. Aunque tu lo abres y se supone que esta al principio. Si tuvieras varias claves en el fichero, libro-id, nombre, editorial podrias leer secuencialmente por esa clave. Incluso no desde el principio sino desde un a determinada posicion.
2) read next lee el siguiente por la clave especificada en el start. Cuando llega al final mete un 10 en el file status.

NOTA. Para este bucle de lectura es recomendable hacer un "OPEN INPUT" en vez de "OPEN I-O" porque si hay varios usuarios trabajando te podrias encontrar un registro bloqueado. Entonces la solucion es leer con una apertura "open input" si no tendrias que hacer lecturas con la clausula "with no lock" para no bloquear registros ni encontrartelos bloqueados.

- - - Updated - - -

Metidos en el tema, suponte que deseas seleccionar un intevalo de libros:

accept libro-desde
accept libro-hasta


VER-LIBROS.
PERFORM LIMPIAR-PANTALLA
PERFORM ABRIR-IO-ARCHIVO
IF F-NOEXISTE-REG THEN
PERFORM LIMPIAR-PANTALLA
DISPLAY "ERROR, NO EXISTE UN ARCHIVO DE REGISTROS" AT LINE 1
COL 1

DISPLAY "PRESIONE ENTER PARA VOLVER AL MENU()" AT LINE 10
COL 1
ACCEPT OPC AT LINE 11 COL 36
ELSE
PERFORM LIMPIAR-PANTALLA

move libro desde to libro-id
if libro-hasta = 0 then move 999 to libro-hasta end-if

start reg-libros key is >= libro-id end-start
READ REG-LIBROS next record end-read

PERFORM VARYING N FROM 1 BY 1 UNTIL fin-reg or libro-id > libro-hasta
DISPLAY DATOS-LIBRO AT LINE N COL 1
READ REG-LIBROS next record end-read
END-PERFORM
ADD 1 TO N
DISPLAY "PRESIONE ENTER PARA REGRESAR AL MENU" AT LINE N
COL 1
ACCEPT OPC AT LINE 15
PERFORM CERRAR-ARCHIVO
END-IF.

[Marengo97]

Muchas gracias cantero, lo voy a tener en cuenta. ;)

[Marengo97]

@JCantero

Me encontre con un problema, si quiero registrar un libro en la opcion 1, suponete tengo dos libros, solo me muestra el ultimo que ingrese.

[Marengo97]

Ya lo solucione...estaba abriendo como output y me creaba un nuevo archivo cada vez, hace rato no uso cobol y me olvido cosas muy fundamentales :silba: