Tema: SQlite3 con PowerCobol
Ver Mensaje Individual
  #1
Antiguo 28 de abril de 2023, 13:22
fastpho
El Foro es mi casa
Innovación: Por aportar innovaciones - Issue reason: SQLite + OO Cobol class Concurso: Primer puesto: Ganador/a del Primer puesto en un concurso - Issue reason: Acceso a datos Cobol vía web 
Última Actividad 21.08.2026 18:08
Posts Posts: 365
Likes enviados Enviados: 252
Likes recibidos Recibidos: 243
Tableta SQlite3 con PowerCobol
5
Likes

David
Josber
Joseg
Kuk
Nitzer

 Inactivo Inactivo
Permite integrar el motor de base de datos de SQlite con nuestras aplicaciones.
En mi caso es para poder interactuar con una aplicacion que hice para Android
y poder leer la informacion de la BD y evitar utilizar archivos con formato .CSV
como interface.
Su implementacion es muy sencilla descargar Binarios precompilados
para Windows para su version 32 bits (sqlite3.dll) no hace falta registrarla.

1 - Copiar Sqlite3.dll en la carpeta del proyecto
2 - Agregar la funciones de la libreria en el Archivo COBOL85
3 - Luego llamar a esas funciones via call
4 - Informacion de las funciones en : https://sqlite.org/c3ref/funclist.html

Ejemplo para abrir , crear , insertar , actualizar un registro y cerrar

Declaracion Variables
Código COBOL:
  1.  01  BD-HANDLE                      PIC 9(9) COMP-5  IS GLOBAL. *>Handle de la BD
  2.  01  BD-FILE-NAME                   PIC X(50)        IS GLOBAL. *>Nombre de la BD
  3.  01  BD-SQL-QUERY                   PIC X(256)       IS GLOBAL. *>string sql (Create , Insert , Delete , Update , Select)
  4.  01  BD-SQL-STRING-LENGHT           PIC S9(9) COMP-5 IS GLOBAL.
  5.  01  BD-HANDLE-STMT                 PIC 9(9) COMP-5  IS GLOBAL.  *>Puntero Statement
  6.  01  BD-STMT-PTR REDEFINES BD-HANDLE-STMT POINTER    IS GLOBAL.  *>Redefines del Puntero Statement
  7.  
  8.  01  BD-INT-POINTER                 POINTER          IS GLOBAL.
  9.  01  BD-INT                         PIC 9(9) COMP-5  IS GLOBAL. *> INTEGER
  10.  01  BD-DOB                         PIC 9(9) COMP-5  IS GLOBAL. *> DOUBLE 
  11.  
  12.  01  BD-TEXT-POINTER                POINTER          IS GLOBAL.
  13.  01  BD-TEXT                        PIC X(256)       IS GLOBAL. *> TEXT 
  14.  01  BD-SQL-ERROR                   POINTER          IS GLOBAL.
  15.  
  16.  
  17.  01  BD-FILA-ID                     PIC 9(9) COMP-5  IS GLOBAL.
  18.  01  BD-COLUMNA-CANTIDAD            PIC 9(9) COMP-5  IS GLOBAL.
  19.  01  BD-COLUMNA-NUMERO              PIC 9(9) COMP-5  IS GLOBAL. 
  20.  01  BD-COLUMNA-NOMBRE              PIC X(256)       IS GLOBAL.
  21.  01  BD-COLUMNA-POINTER             POINTER          IS GLOBAL.
  22.  
  23.  
  24. * Estado de la Base de Datos
  25.  01  BD-STATUS                      PIC 9(9) COMP-5  IS GLOBAL. 
  26.  *>Estado de la BD
  27.  01  ESTADOS-BD IS GLOBAL.
  28.      03 SQLITE_OK       PIC 9(9) COMP-5  VALUE 0.   *> /* Successful result */
  29.      03 SQLITE_ERROR    PIC 9(9) COMP-5  VALUE 1.   *> /* Generic error */
  30.      03 SQLITE_BUSY     PIC 9(9) COMP-5  VALUE 5.   *> /* The database file is locked */
  31.      03 SQLITE_LOCKED   PIC 9(9) COMP-5  VALUE 6.   *> /*  A table in the database is locked */
  32.      03 SQLITE_READONLY PIC 9(9) COMP-5  VALUE 8.   *> /*  Attempt to write a readonly database */
  33.      03 SQLITE_EMPTY    PIC 9(9) COMP-5  VALUE 16.  *> /*  Attempt to write a readonly database */
  34.      
  35.      
  36.      03 SQLITE_MISUSE   PIC 9(9) COMP-5  VALUE 21.  *> /* Library used incorrectly */
  37.      03 SQLITE_WARNING  PIC 9(9) COMP-5  VALUE 28.  *> /* unusual and possibly ill-advised operation is taking place.*/
  38.      
  39.      03 SQLITE-ROW      PIC 9(9) COMP-5  VALUE 100. *> /* sqlite3_step() has another row ready */ 
  40.      03 SQLITE-DONE     PIC 9(9) COMP-5  VALUE 101. *> /* sqlite3_step() has finished executing */
  41. * Tipos de Datos sqlite     
  42.  01  BD-COLUMNA-TIPO       PIC 9(4) COMP-5 IS GLOBAL.
  43.       88  SQL-INTEGER        VALUE 1. *> 
  44.       88  SQL-REAL           VALUE 2. *>  
  45.       88  SQL-TEXT           VALUE 3. *> 
  46.       88  SQL-BLOB           VALUE 4. *> 
  47.       88  SQL-NULL           VALUE 5. *> 
  48.      
  49.  
  50.  01 FECHA-CONVERTIR       PIC 9(8)         IS GLOBAL. *> AAAAMMDD a Convertir 
  51.  01 FECHA-CONVERTIDA-UNIX PIC 9(13)        IS GLOBAL. *> Fecha con formato unix
  52.  01 FECHA-UNIX1970        PIC S9(9) COMP-5 IS GLOBAL. *> desde AAAAMMDDD 19700101
  53.  01 FECHA-INT             PIC S9(9) COMP-5 IS GLOBAL. 
  54.  01 FECHA-AMD             PIC 9(8)         IS GLOBAL.
  55.  01 FECHA-AMD-ED          PIC XXXX/XX/XX   IS GLOBAL.
  56.  
  57.  01 NULO                           PIC 9(9)  COMP-5 VALUE 0 IS GLOBAL.    *> NULO
  58.  
  59.  *>[url]https://sqlite.org/cintro.html[/url]
  60.  *>Funciones de la libreria sqlit3.dll
  61.  *>[url]https://sqlite.org/c3ref/funclist.html[/url]
  62.  *>Funciones Declaradas en el archivo COBOL85.CBR
  63.  *>Fecha 17-04-2023
  64.  01  FUNCIONES-SQLITE3-LIB          PIC X(50)        IS GLOBAL. 
  65. *> sqlite3-connection functions
  66.     *>  sqlite3_libversion (OUT <text>)                                                  *> Devuelve la versión de sqlite a través del parámetro OUT. OK probado
  67.     *>  sqlite3_libversion_number (OUT <int>                   )                         *> Devuelve el número de versión como un int  OK probado
  68.     *>  sqlite3_open       (<nombre de archivo>, OUT <controlador de la base de datos>). *> Esto abre un archivo de base de datos SQLite , nueva o existente como se especifica en el argumento de nombre de archivo.OK probado
  69.     *>  sqlite3_close       (<db-handle>)(<identificador de la base de datos>)           *> Destructor de la interface , cierra la BD OK probado
  70.     *>  sqlite3_exec       (<gestor-bd>,<cadena-sql>)                                    *> Es una envoltura  sqlite3_prepare_v2(), sqlite3_step() y sqlite3_finalize() OK probado
  71.     *>  sqlite3_errmsg     (<db-handle>, OUT <mensaje de error)                          *> Devuelve texto en inglés como un parámetro OUT que describe el último error en la conexión. OK probado
  72.  
  73. *> sqlit3-statement functions    
  74.    *> sqlite3_prepare_v2  *>Constructor OK probado
  75.    *> sqlite3_finalize    *>Destructor  OK probado
  76.       *> Pass
  77.          *> sqlite3_step         int sqlite3_step(sqlite3_stmt*);  OK probado 
  78.          *> sqlite3_reset        int sqlite3_reset(sqlite3_stmt *pStmt); OK probado
  79.          *> sqlite3_finalize     int sqlite3_finalize(sqlite3_stmt *pStmt); OK probado
  80.          
  81.       *> Statement column access (0-base indices) 
  82.          *> sqlite3_column_count    int sqlite3_column_count(sqlite3_stmt *pStmt);   OK probado 
  83.          *> sqlite3_column_type     int sqlite3_column_type(sqlite3_stmt*, int iCol);  OK probado
  84.          *> sqlite3_column_name     const char *sqlite3_column_name(sqlite3_stmt*, int N); OK probado
  85.       *> Statement column type 
  86.          *> sqlite3_column_int      int sqlite3_column_int(sqlite3_stmt*, int iCol);  OK probado
  87.          *> sqlite3_column_text     const unsigned char *sqlite3_column_text(sqlite3_stmt*, int iCol);   OK probado
  88.          *> sqlite3_column_double   double sqlite3_column_double(sqlite3_stmt*, int iCol);   OK probado
  89.          *> sqlite3_column_blob     no implementado
  90.  

Abrir BD

Código COBOL:
  1. *------------------------------------------------------------------     
  2. *>sqlite3_open
  3. *    DISPLAY "------------".
  4. *    DISPLAY "sqlite3_open". 
  5.  
  6.      MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
  7.      MOVE "sqlite3_open"         TO FUNCIONES-SQLITE3-LIB.    
  8.      MOVE "datos.db"  & X"00"    TO BD-FILE-NAME.
  9.      
  10.      call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
  11.               USING BY REFERENCE BD-FILE-NAME
  12.                     BY REFERENCE BD-HANDLE 
  13.              returning  BD-STATUS
  14.  
  15.      end-call.
  16.      IF BD-STATUS  NOT = SQLITE_OK THEN
  17.         CALL "BD-ERROR"
  18.      ELSE
  19.         MOVE  "OK" TO "Caption" OF CmStatic2
  20.      END-IF.    

Crear BD

Código COBOL:
  1. *------------------------------------------------------------------     
  2. *>sqlite3_exec
  3. *    DISPLAY "------------".
  4. *    DISPLAY "sqlite3_exec". 
  5. *    DISPLAY "CREATE". 
  6.      MOVE SPACES                 TO BD-SQL-QUERY.
  7.      MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
  8.      MOVE "sqlite3_exec"         TO FUNCIONES-SQLITE3-LIB.    
  9.      MOVE "CREATE TABLE usuarios (id INTEGER PRIMARY KEY AUTOINCREMENT  , nombre TEXT , edad INTEGER )" & X"00" TO BD-SQL-QUERY.
  10.  
  11.      call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
  12.               USING 
  13.                     BY VALUE   BD-HANDLE
  14.                     BY CONTENT BD-SQL-QUERY
  15.               BY VALUE 0
  16.               BY VALUE 0
  17.               BY VALUE 0
  18.              returning  BD-STATUS
  19.  
  20.      end-call.
  21.      
  22.  
  23.      IF BD-STATUS NOT = SQLITE_OK THEN
  24.         CALL "BD-ERROR"
  25.      ELSE 
  26.         MOVE "OK" TO "Caption" OF CmStatic2
  27.      END-IF.
  28.      

Insertar Registro BD

Código COBOL:
  1. *------------------------------------------------------------------     
  2. *>sqlite3_exec
  3. *    DISPLAY "------------------".
  4. *    DISPLAY "sqlite3_exec". 
  5. *    DISPLAY "INSERT". 
  6.  
  7.      MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
  8.      MOVE "sqlite3_exec"         TO FUNCIONES-SQLITE3-LIB.    
  9.  
  10.      MOVE SPACES                 TO BD-SQL-QUERY.    
  11.      string "INSERT INTO usuarios (nombre , edad ) " delimited by size  
  12.             " VALUES ('Leonardo' , 24 )" delimited by size 
  13.             x"00" delimited by size
  14.             into BD-SQL-QUERY
  15.      end-string.
  16.  
  17.      
  18.      call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
  19.               USING 
  20.                     BY VALUE   BD-HANDLE
  21.                     BY CONTENT BD-SQL-QUERY
  22.               BY VALUE 0
  23.               BY VALUE 0
  24.               BY VALUE 0
  25.              returning  BD-STATUS
  26.  
  27.      end-call.
  28.      IF BD-STATUS NOT = SQLITE_OK 
  29.         CALL "BD-ERROR"
  30.      END-IF.

Actualizar Registro BD
Código COBOL:
  1.  PROCEDURE       DIVISION.
  2. *------------------------------------------------------------------     
  3. *>sqlite3_exec
  4. *    DISPLAY "------------------".
  5. *    DISPLAY "sqlite3_exec". 
  6. *    DISPLAY "UPDATE". 
  7.  
  8.      MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
  9.      MOVE SPACES                 TO BD-SQL-QUERY.         
  10.      MOVE "sqlite3_exec"         TO FUNCIONES-SQLITE3-LIB.
  11.  
  12.  
  13.      string "UPDATE usuarios SET  nombre = 'xxxx' " delimited by size  
  14.             "  WHERE id = 1" delimited by size 
  15.             x"00" delimited by size
  16.             into BD-SQL-QUERY
  17.      end-string.
  18.  
  19.      
  20.      call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
  21.               USING 
  22.                     BY VALUE   BD-HANDLE
  23.                     BY CONTENT BD-SQL-QUERY
  24.               BY VALUE 0
  25.               BY VALUE 0
  26.               BY VALUE 0
  27.              returning  BD-STATUS
  28.  
  29.      end-call.
  30.      
  31.      IF BD-STATUS NOT = SQLITE_OK 
  32.         CALL "BD-ERROR"
  33.      ELSE
  34.         MOVE  "OK" TO "Caption" OF CmStatic2
  35.      END-IF.

Cerar BD
Código COBOL:
  1. *------------------------------------------------------------------     
  2. *>sqlite3_close
  3. *    DISPLAY "------------".
  4. *    DISPLAY "sqlite3_close". 
  5.  
  6.      MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
  7.      MOVE "sqlite3_close"        TO FUNCIONES-SQLITE3-LIB.    
  8.  
  9.      call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
  10.               USING     BY VALUE BD-HANDLE
  11.              returning  BD-STATUS
  12.  
  13.      end-call.
  14.  
  15.      IF BD-STATUS NOT = SQLITE_OK THEN
  16.         CALL "BD-ERROR"
  17.      ELSE
  18.         MOVE  "OK" TO "Caption" OF CmStatic2        
  19.      END-IF.

Saludos....
fastpho is offline   Responder Con Cita