Ventanas Flotantes

[Kuk]

@Nitzer, de nada hombre, para eso estamos

En cuanto a lo de los hilos, es perfectamente posible. Había un ejemplo de Rapinto por ahí en el foro.

En todo caso, la mecánica sería de crear un Thread vía WinAPI, declarar un PROCEDURE-POINTER, hacerle un

     SET MI-PROCEDURE-POINTER TO ENTRY "NOMBRE_PROCEDURE"

Y pasar MI-PROCEDURE-POINTER redefinido en PIC S9(9) COMP-5 al Thread creado.

Ando mal de tiempo, pero intento hacer un ejemplo mañana

Aunque lo más fácil es usar CmTimer-s, porque cada uno crea un hilo detrás. Es decir, poner un CmTimer en el Form, poner en su evento el código que queramos, y lo primero lo que debemos hacer es parar el timer dentro de ese código. Y para invocarlo, simplemente activar el Timer.

[Nitzer]

Kuk, sin prisas, si pasas un ejemplo, te estaré eternamente agradecido

Como sabes yo siempre utilizo OPENFORM, es decir que desde el menu, cualquier usuario puede tener todas las ventanas que quiera abiertas, obviamente de programas distintos, pero claro, cuando lanzo una consulta que tarda deja todo el programa "no responde"

Gracias como siempre por todo.

[Kuk]

@Nitzer, estoy en ello, ¡lo prometido es deuda!

Lo que pasa es que lo estoy haciendo desde 0 porque no encontré el ejemplo del que hablaba y no tengo tiempo ni para estornudar...

Sólo para enseñarte mis avances, de momento no funciona bien:

 ENVIRONMENT     DIVISION.
 DATA            DIVISION.
 WORKING-STORAGE SECTION.
 01  RESP                       PIC S9(9) COMP-5.
 01  SECURITY-DESCRIPTOR.
     05  Revision               PIC X(1). 
     05  Sbz1                   PIC X(1). 
     05  sControl               PIC S9(4) COMP-5. *> SECURITY_DESCRIPTOR_CONTROL
     05  sOwner                 PIC S9(9) COMP-5.
     05  sGroup                 PIC S9(9) COMP-5.
     05  Sacl                   PIC S9(9) COMP-5.
     05  Dacl                   PIC S9(9) COMP-5.
 
 01  lpdwRevision               PIC S9(9) COMP-5.
 
 01  SECURITY-ATTRIBUTES.
     05  nLength                PIC S9(9) COMP-5. *> The size, in bytes, of this structure
     05  lpSecurityDescriptor   POINTER. *> A pointer to a SECURITY_DESCRIPTOR structure     
     05  bInheritHandle         PIC 9(2) COMP-5.  *> A Boolean value that specifies whether the returned handle is inherited when a new process is created. 
 
 01  dwStackSize                PIC 9(9) COMP-5. *> The initial size of the stack, in bytes. The system rounds this value to the nearest page. If this parameter is zero, the new thread uses the default size for the executable. 
 01  lpStartAddress             PROCEDURE-POINTER.
 01  R-lpStartAddress REDEFINES lpStartAddress PIC 9(9) COMP-5.
 
 01  lpParameter                PIC 9(9) COMP-5.
 01  dwCreationFlags            PIC 9(9) COMP-5. *> if 0 - The thread runs immediately after creation. 
 01  lpThreadId                 PIC 9(9) COMP-5. *> A pointer to a variable that receives the thread identifier.
 PROCEDURE       DIVISION.
     
     MOVE POW-FALSE TO "Enabled" OF CmCommand1
     
     *>Advapi32.lib
*    CALL "GetSecurityDescriptorControl" WITH STDCALL USING BY REFERENCE SECURITY-DESCRIPTOR
*                                                           BY REFERENCE sControl
*                                                           BY REFERENCE lpdwRevision
*                                                           RETURNING RESP
     
     CALL "InitializeSecurityDescriptor" WITH STDCALL USING BY REFERENCE SECURITY-DESCRIPTOR
                                                            BY VALUE 1
                                                            RETURNING RESP
     
     IF  RESP = ZEROS
         CALL "GetLastError" WITH STDCALL RETURNING RESP
         
         DISPLAY "ERROR GetSecurityDescriptorControl, RC: " RESP            
         
         EXIT PROGRAM
     END-IF
     
     MOVE LENGTH OF SECURITY-ATTRIBUTES TO nLength
     
     SET lpSecurityDescriptor TO ADDRESS OF SECURITY-DESCRIPTOR
     
     MOVE H"00" TO bInheritHandle
     MOVE 0     TO dwStackSize
     
     SET lpStartAddress TO ENTRY "RUTINA@0"
     
     MOVE 0 TO lpParameter
     
     *> Kernel32.lib
     CALL "CreateThread" WITH STDCALL USING BY REFERENCE SECURITY-ATTRIBUTES
                                            BY VALUE dwStackSize
                                            BY VALUE R-lpStartAddress
                                            BY REFERENCE lpParameter
                                            BY VALUE dwCreationFlags
                                            BY REFERENCE lpThreadId
                                            RETURNING RESP
                                            
     IF  RESP = ZEROS
         CALL "GetLastError" WITH STDCALL RETURNING RESP
         
         DISPLAY "ERROR CreateThread, RC: " RESP            
         
         EXIT PROGRAM
     END-IF
     
     PERFORM 10 TIMES
         INVOKE CmList1 "AddString" USING "¡Este es el Thread del Form!"
     
         CALL "Sleep" WITH STDCALL USING BY VALUE 1000
     END-PERFORM                            

---------- Post añadido : 21:59 ---------- Post anterior : 22:42 ----------

@Nitzer, malas noticias. Es posible hacerlo en COBOL, pero no en Fujitsu, porque el último no trabaja con parámetros BY VALUE. Es decir, necesitaríamos algo como esto:

 IDENTIFICATION DIVISION.
 PROGRAM-ID. "RUTINA".
 
 DATA DIVISION.
 LINKAGE SECTION.
 01  P-THREAD            POINTER.
 PROCEDURE DIVISION WITH STDCALL LINKAGE USING BY VALUE P-THREAD.
 

Y parece ser que la función que pasamos a la hora de crear el nuevo Thread lo necesita para poder gestionarlo:

DWORD WINAPI mythread(LPVOID lpParameter){

Así que, lo que se podría intentar es pasar por una pasarela en C (crear une DLL intermediaria). Pero para probar esto necesito aún más tiempo. No sé cuándo lo voy a poder hacer.

Así que de momento te propongo que pruebes la otra solución de usar Timers como funciones en un Thread separado, a mi me ha funcionado de maravilla.

[Nitzer]

Kuk, tranquilo, no quiero quitarte mas tiempo )

Eternamente agradecido por el trabajo que haces por todos nosotros.

NO es algo que me quite la vida.

MIs compañeros ya están con .NET C# a tope y poco a poco iré programando menos yo y mas ellos.

Me voy a dedicar mas a pensar (análisis), la empresa no para de crecer y no me queda otra.

[Kuk]

@Nitzer, ¡¡¡¡¡¡¡ Lo conseguí !!!!!!!!! Y sin pasarelas ni ostias. Puro Fujitsu COBOL.

El código mágico: (dejo el proyecto entero en adjuntos)

IMPORTANTE: si haces DISPLAY, tienes que hacer el primero en el Thread el Form, luego haces el resto en el nuevo Thread.

 ENVIRONMENT     DIVISION.
 DATA            DIVISION.
 WORKING-STORAGE SECTION.
 01  RESP                       PIC S9(9) COMP-5.
 01  lpStartAddress             PROCEDURE-POINTER.
 01  R-lpStartAddress REDEFINES lpStartAddress PIC 9(9) COMP-5.
 01  lpParameter                PIC 9(9) COMP-5.
 01  lpThreadId                 PIC 9(9) COMP-5 VALUE 0. 
 
 01  CAMPO       PIC X(20) IS EXTERNAL.
 PROCEDURE       DIVISION.
     
     DISPLAY "Vamos allá..."
     
     MOVE "Hola desde el Form!" TO CAMPO
     
     MOVE POW-FALSE TO "Enabled" OF CmCommand1
     
     SET lpStartAddress TO ENTRY "RUTINA@0"
          
     *> Kernel32.lib
     CALL "CreateThread" WITH STDCALL USING BY VALUE 0 
                                            BY VALUE 0 
                                            BY VALUE R-lpStartAddress
                                            BY REFERENCE lpParameter
                                            BY VALUE 0
                                            BY REFERENCE lpThreadId
                                            RETURNING RESP
                                            
     IF  RESP = ZEROS
         CALL "GetLastError" WITH STDCALL RETURNING RESP
         
         DISPLAY "ERROR CreateThread, RC: " RESP            
         
         EXIT PROGRAM
     END-IF

 IDENTIFICATION DIVISION.
 PROGRAM-ID. "RUTINA".
 
 DATA DIVISION.
 WORKING-STORAGE SECTION.
 01  CAMPO       PIC X(20) IS EXTERNAL.
 PROCEDURE DIVISION WITH STDCALL LINKAGE.
 
     PERFORM 10 TIMES
         DISPLAY "¡¡¡Este es un nuevo Thread!!! Valor recibido: " CAMPO
     
         CALL "Sleep" WITH STDCALL USING BY VALUE 1000
     END-PERFORM
     
     DISPLAY "ADIÓS"
     
     CALL "Sleep" WITH STDCALL USING BY VALUE 1000
     
     GOBACK
     .
 
 END PROGRAM "RUTINA".

[Nitzer]

Maravilloso, voy a intentar comprender el código y probarlo.
No hay palabras para semejante trabajo )))

[Kuk]

@Nitzer, mantennos al corriente, lógicamente lo he probado pero siempre se te puede escapar algo.

Además, me parece un tema interesante, si el código te parece comprensible o no.


P.D. Sinceramente, nuestro foro me parece el más rico en código "oro" del mundo entero. Al menos de los que yo conozco, incluyendo los que están en inglés.
Quiero decir, tenemos ejemplos que no he visto nunca en ningún otro sitio.

---------- Post añadido : 16:01 ---------- Post anterior : 21:40 ----------

Por si a alguien les interesa cómo hacerlo vía Timer: [Componente] ctList de Dbi Tech - Problema con el Font... - COBOL Foro

[Kuk]

@Nitzer, ¿qué tal, lo has probado?

[Nitzer]

@Nitzer, ¿qué tal, lo has probado?

Hola Kuk, aún no he podido, estoy con un proyecto complejo, pero te prometo que lo voy a hacer, a comprender y a poner aquí la experiencia

Ya puestos te cuento el proyecto con el que estoy full-time

Mejor, mañana tiro fotos y os lo cuento.

[Kuk]

@Nitzer, has podido hacerlo o de momento nada?

Estoy intrigado, verlo en acción sería un placer la verdad