Resultados 1 al 4 de 4

Tema: Obtener la version de SO Windows

  1. #1
      Administrador
    Avatar de Kuk

    Registrado
    enero de 2015
    Edad
    37
    Mensajes
    2,011
    Ciudad
    Madrid

    Agradecimientos
     
    Recibidos
    862
    Enviados
    720

    Citaciones y menciones
     
    Mentioned
    3 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    5 Post(s)
    Poder de Reputación
    10

    Arrow Obtener la version de SO Windows

    COBOL Código:
    1. IDENTIFICATION DIVISION.                                                                   
    2.  PROGRAM-ID.    WINVERS.                                                                     
    3.  AUTHOR.        KUK.                                                                 
    4.  ENVIRONMENT DIVISION.                                                                       
    5.  CONFIGURATION SECTION.                                                                     
    6.  SPECIAL-NAMES.                                                                             
    7.      DECIMAL-POINT IS COMMA.                                                                 
    8.                                                                                              
    9.  DATA DIVISION.                                                                             
    10.                                                                                              
    11.  WORKING-STORAGE SECTION.                                                                   
    12.                                                                                              
    13.  01  OSVERSIONINFO TYPEDEF.                                                                 
    14. * The size of this data structure, in bytes. Set this member to sizeof(OSVERSIONINFO).       
    15.      05  dwOSVersionInfoSize PIC S9(9) COMP-5.                                               
    16. * The major version number of the operating system. For more information, see Remarks.       
    17.      05  dwMajorVersion      PIC S9(9) COMP-5.                                               
    18. * The minor version number of the operating system. For more information, see Remarks.       
    19.      05  dwMinorVersion      PIC S9(9) COMP-5.                                               
    20. * The build number of the operating system.                                                 
    21.      05  dwBuildNumber       PIC S9(9) COMP-5.                                               
    22. * The operating system platform. This member can be the following value:*                   
    23. * - VER_PLATFORM_WIN32_NT = 2                                                               
    24. *   The operating system is Windows 7, Windows Server 2008, Windows Vista,                   
    25. *   Windows Server 2003, Windows XP, or Windows 2000.                                       
    26.      05  dwPlatformId        PIC S9(9) COMP-5.                                               
    27. * A null-terminated string, such as "Service Pack 3", that indicates the latest Service Pack
    28. * installed on the system. If no Service Pack has been installed, the string is empty.       
    29.      05  szCSDVersion        PIC X(128).                                                     
    30.                                                                                              
    31.  01  WS-OSINFO TYPE OSVERSIONINFO.                                                           
    32.  01  STATUS-CODE   PIC S9(4) COMP-5.                                                         
    33.                                                                                              
    34.  LINKAGE SECTION.                                                                           
    35.  01  LNK-WV-DATA.                                                                           
    36.      05  LNK-WV-OUTPUT.                                                                     
    37.          10  LNK-WV-RC          PIC 9(2).                                                   
    38.          10  LNK-WV-VERS        PIC X(100).                                                 
    39.          10  LNK-WV-SP          PIC X(50).                                                   
    40.                                                                                              
    41.  PROCEDURE DIVISION USING LNK-WV-DATA.                                                       
    42.                                                                                              
    43.      INITIALIZE LNK-WV-DATA REPLACING                                                       
    44.          NUMERIC      DATA BY ZEROS                                                         
    45.          ALPHANUMERIC DATA BY SPACES                                                         
    46.                                                                                              
    47.      MOVE 148 TO dwOSVersionInfoSize OF WS-OSINFO                                           
    48.                                                                                              
    49.      CALL "GetVersionExA" WITH STDCALL USING BY REFERENCE WS-OSINFO RETURNING STATUS-CODE   
    50.                                                                                              
    51.      IF  STATUS-CODE = ZEROS                                                                 
    52.          MOVE 99 TO LNK-WV-RC                                                               
    53.                                                                                              
    54.          MOVE SPACES TO LNK-WV-VERS                                                         
    55.                                                                                              
    56.          GOBACK                                                                             
    57.      END-IF                                                                                 
    58.                                                                                              
    59.      MOVE ZEROS TO LNK-WV-RC                                                                 
    60.                                                                                              
    61.      EVALUATE TRUE ALSO TRUE                                                                 
    62.                                                                                              
    63.          WHEN dwMajorVersion = 6                                                             
    64.          ALSO dwMinorVersion = 3                                                             
    65.              MOVE "Windows 8.1"         TO LNK-WV-VERS                                       
    66.                                                                                              
    67.          WHEN dwMajorVersion = 6                                                             
    68.          ALSO dwMinorVersion = 2                                                             
    69.              MOVE "Windows 8"           TO LNK-WV-VERS                                       
    70.                                                                                              
    71.          WHEN dwMajorVersion = 6                                                             
    72.          ALSO dwMinorVersion = 1                                                             
    73.              MOVE "Windows 7"           TO LNK-WV-VERS                                       
    74.                                                                                              
    75.          WHEN dwMajorVersion = 6                                                             
    76.          ALSO dwMinorVersion = 0                                                             
    77.              MOVE "Windows Vista"       TO LNK-WV-VERS                                       
    78.                                                                                              
    79.          WHEN dwMajorVersion = 5                                                             
    80.          ALSO dwMinorVersion = 2                                                             
    81.              MOVE "Windows Server 2003" TO LNK-WV-VERS                                       
    82.                                                                                              
    83.          WHEN dwMajorVersion = 5                                                             
    84.          ALSO dwMinorVersion = 1                                                             
    85.              MOVE "Windows XP"          TO LNK-WV-VERS                                       
    86.                                                                                              
    87.          WHEN dwMajorVersion = 5                                                             
    88.          ALSO dwMinorVersion = 0                                                             
    89.              MOVE "Windows 2000"        TO LNK-WV-VERS                                       
    90.                                                                                              
    91.          WHEN OTHER                                                                         
    92.              MOVE "Windows UNKNOWN"     TO LNK-WV-VERS                                       
    93.                                                                                              
    94.      END-EVALUATE                                                                           
    95.                                                                                              
    96.      INSPECT szCSDVersion REPLACING ALL X"00" BY SPACES                                     
    97.                                                                                              
    98.      MOVE szCSDVersion TO LNK-WV-SP                                                         
    99.                                                                                              
    100.      GOBACK                                                                                 
    101.      .                                                                                       

    0 Not allowed!

    ¿Te han ayudado? NO TE OLVIDES de darle al botón
    ¿Quieres dirigirte a alguien en tu post? Notifícale con una mención, tienes 2 opciones:
    1. Haciendo clic en el icono al lado de su nick
    2. Haciendo clic en el editor al botón y escribiendo su nick.

  2. #2
      Acabo de llegar...
    e

    Registrado
    julio de 2016
    Mensajes
    21
    Ciudad
    Azuay

    Agradecimientos
     
    Recibidos
    6
    Enviados
    0

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    0

    Predeterminado

    estimados por que no usar la sentencia

    COBOL Código:
    1. ACCEPT SYSTEM-INFORMATION FROM SYSTEM-INFO.

    Donde SYSTEM-INFO saca toda la informacion del sisyema del equipo que se usa ... tipo os... version...usuario ... dominio etc..etc y lo recolecta anivel de la workin den SYSTEM-INFORMATION
    COBOL Código:
    1. 01  SYSTEM-INFORMATION.
    2.            03  OPERATING-SYSTEM                PIC X(10).
    3.                88  OS-IS-MSDOS                 VALUE "MS-DOS".
    4.                88  OS-IS-OS2                   VALUE "OS/2".
    5.                88  OS-IS-VMS                   VALUES "VMS",
    6.                                                "VAX/VMS".
    7.                88  OS-IS-UNIX                  VALUES "Unix",
    8.                                                       "Unix-V", "Unix-4",
    9.                                                       "UNOS".
    10.                88  OS-IS-AOS                   VALUE "AOS/VS".
    11.                88  OS-IS-WINDOWS               VALUE "WINDOWS".
    12.                88  OS-IS-WIN-NT                VALUE "WIN/NT".
    13.                88  OS-IS-WIN-FAMILY            VALUES "WINDOWS",
    14.                                                       "WIN/NT".
    15.                88  OS-IS-AMOS                  VALUE "AMOS".
    16.                88  OS-IS-MPE                   VALUE "MPE/iX".
    17.                88  OS-IS-MPEIX                 VALUE "MPE/iX".
    18.            03  USER-ID                         PIC X(12).
    19.            03  STATION-ID                      PIC X(12).
    20.            03  FILLER                          PIC X.
    21.                88  HAS-INDEXED-READ-PREVIOUS   VALUE "Y".
    22.            03  FILLER                          PIC X.
    23.                88  HAS-RELATIVE-READ-PREVIOUS  VALUE "Y".
    24.            03  FILLER                          PIC X.
    25.                88  CAN-TEST-INPUT-STATUS       VALUE "Y".
    26.            03  FILLER                          PIC X.
    27.                88  IS-MULTI-TASKING            VALUE "Y".
    28.            03  RUNTIME-VERSION.
    29.                88  VERSION-PRIOR-TO-2-2        VALUE SPACES.
    30.                05  RUNTIME-MAJOR-VERSION       PIC 99.
    31.                05  RUNTIME-MINOR-VERSION       PIC 99.
    32.                05  RUNTIME-RELEASE             PIC 99.
    33.            03  FILLER                          PIC X.
    34.                88  IS-PLUGIN                   VALUE "Y".
    35.            03  SERIAL-NUMBER                   PIC X(20).
    36.            03  FILLER                          PIC X.
    37.                88  HAS-LARGE-FILE-SUPPORT      VALUE "Y".

    0 Not allowed!

  3. #3
      Administrador
    Avatar de Kuk

    Registrado
    enero de 2015
    Edad
    37
    Mensajes
    2,011
    Ciudad
    Madrid

    Agradecimientos
     
    Recibidos
    862
    Enviados
    720

    Citaciones y menciones
     
    Mentioned
    3 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    5 Post(s)
    Poder de Reputación
    10

    Predeterminado

    @eage1969, esa sentencia a qué compilador pertenece? Imagino que es de ACU o RM.

    No lo he probado, pero para mi que no es compatible con PowerCOBOL. Sobre todo porque preguntar en Power si el SO es Unix u otro que no sea Windows no tiene sentido ninguno ya que PowerCOBOL sólo existe para Windows.

    0 Not allowed!

    ¿Te han ayudado? NO TE OLVIDES de darle al botón
    ¿Quieres dirigirte a alguien en tu post? Notifícale con una mención, tienes 2 opciones:
    1. Haciendo clic en el icono al lado de su nick
    2. Haciendo clic en el editor al botón y escribiendo su nick.

  4. #4
      Acabo de llegar...
    e

    Registrado
    julio de 2016
    Mensajes
    21
    Ciudad
    Azuay

    Agradecimientos
     
    Recibidos
    6
    Enviados
    0

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    0

    Predeterminado

    Hola buenas noches..
    perdón por responder tarde ...pertenece a para cualquiera de las versiones de Cobol.

    0 Not allowed!

Información de Tema

Usuarios Viendo este Tema

Actualmente hay 1 usuarios viendo este tema. (0 miembros y 1 visitantes)

Temas Similares

  1. [Sintaxis] Obtener version de Windows en ejecución
    Por Hector en el foro PowerCOBOL (ActiveX, v4 - v11)
    Respuestas: 1
    Último Mensaje: 04.05.2018, 22:35
  2. [Información] ¿Existe alguna version de RM/Cobol gratuita?
    Por JuanPelaez en el foro RM/COBOL
    Respuestas: 1
    Último Mensaje: 27.04.2018, 18:26
  3. [Información] ¿Existe alguna version de NetCobol gratuita?
    Por JuanPelaez en el foro NetCOBOL for Windows
    Respuestas: 9
    Último Mensaje: 27.04.2018, 12:14
  4. [Sintaxis] Obtener el Directorio de la aplicación
    Por Eslopes en el foro PowerCOBOL V3L10 (Win32)
    Respuestas: 2
    Último Mensaje: 21.06.2016, 15:26
  5. [Aporte] Obtener el Handle (HWND) de un control
    Por Kuk en el foro Cocina PowerCOBOL V3L10
    Respuestas: 0
    Último Mensaje: 21.12.2015, 21:53

User Tag List

Permisos de Publicación

  • No puedes crear nuevos temas
  • No puedes responder temas
  • No puedes subir archivos adjuntos
  • No puedes editar tus mensajes
  •