Resultados 1 al 8 de 8

Tema: OCX WSAFIPFE facturas electronicas (en Argentina)

  1. #1
      Acabo de llegar...
    m

    Registrado
    octubre de 2017
    Edad
    61
    Mensajes
    3
    Ciudad
    Cordoba / Rio Cuarto

    Agradecimientos
     
    Recibidos
    0
    Enviados
    1

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    0

    Impresora OCX WSAFIPFE facturas electronicas (en Argentina)

    Buenas Tardes, esta pregunta es para los que estan usando el OCX WSAFIPFE de Carusso para realizar facturas electronicas (en Argentina), me sucede que en mi powercobol 7 u 9 cualquiera de las 2 versiones
    no puedo incorpararlo a la toolbox del formulario, lo visualizo al OCX pero no me deja insertarlo a la barra para despues pasarlo al formulario, les a sucedido esto ? o estoy haciendo algom mal ?, gracias por su colaboracion.

    0 Not allowed!

  2. #2
      Administrador Avatar de Kuk

    Registrado
    enero de 2015
    Edad
    37
    Mensajes
    2,010
    Ciudad
    Madrid

    Agradecimientos
     
    Recibidos
    860
    Enviados
    718

    Citaciones y menciones
     
    Mentioned
    1 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    5 Post(s)
    Poder de Reputación
    10

    Predeterminado

    @marcelolarran, qué error te da exactamente? Ojo, a partir de Windows 7 debes ejecutar PowerCOBOL como Administrador, para poder registrar las OCX.

    0 Not allowed!

    ¿Te han ayudado? NO TE OLVIDES de darle al botón
    ¿Quieres dirigirte a alguien en tu post? Notifícale con una mención, tienes 2 opciones:
    1. Haciendo clic en el icono al lado de su nick
    2. Haciendo clic en el editor al botón y escribiendo su nick.

  3. #3
      Acabo de llegar...
    m

    Registrado
    octubre de 2017
    Edad
    61
    Mensajes
    3
    Ciudad
    Cordoba / Rio Cuarto

    Agradecimientos
     
    Recibidos
    0
    Enviados
    1

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    0

    Predeterminado

    el OCX esta bien instalado, como administrador obviamente, logre incorporarlo a toolbox del formulario, pero cuando ejecuto el propgrama para pedir el CAE me sale el mensaje "Referencia a Objeto no establecida como instancia de un objeto", lei las soluciones al problema, poero no logro darme cuenta porque use el mismo ejemplo que esta en la pagina de CAMUSSO.

    0 Not allowed!

  4. #4
      Administrador Avatar de Kuk

    Registrado
    enero de 2015
    Edad
    37
    Mensajes
    2,010
    Ciudad
    Madrid

    Agradecimientos
     
    Recibidos
    860
    Enviados
    718

    Citaciones y menciones
     
    Mentioned
    1 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    5 Post(s)
    Poder de Reputación
    10

    Predeterminado

    @marcelolarran, revisa las dependencias, lo mismo debes tener instalado algún componente más, como por ejemplo alguna versión de C++ Redistributable o similar.

    0 Not allowed!

    ¿Te han ayudado? NO TE OLVIDES de darle al botón
    ¿Quieres dirigirte a alguien en tu post? Notifícale con una mención, tienes 2 opciones:
    1. Haciendo clic en el icono al lado de su nick
    2. Haciendo clic en el editor al botón y escribiendo su nick.

  5. #5
      Forero
    G

    Registrado
    febrero de 2015
    Edad
    67
    Mensajes
    180
    Ciudad
    Quilmes, Buenos Aires

    Agradecimientos
     
    Recibidos
    118
    Enviados
    89

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    19
    Concurso: Segundo puesto / Point Value: 0 Activista del Foro / Point Value: 0

    Predeterminado

    @marcelolarran, Yo tambien tuve problemas con esta ocx, es mas, hablé con el sr. Camusso y vía teamviewer el mismo se metió en mi computadora para ver si encontraba el problema, pero al no tener conocimientos de AcuCobol no logró ayudarme.

    La única forma que encontré de poder hacer facturas electrónicas fue a través de la interfase any2fe, la cual funciona como interlocutora entre mi programa y WSAFIPFE. Es mas cara, pero me permitió resolver el problema.

    Viene con un instalador el cual se encarga de la instalación de WSAFIPFE, luego con tu programa generas un par de archivitos con los datos de la factura y llamas a any2fe.exe con los parámetros necesarios y asunto resuelto. Solicitaa la autorización y si todo anduvo bien te devuelve el CAE.

    Hay otra interfase (PYAFIPWS) que tengo entendido que es gratis, pero bueno, ya había comprado la otra.

    0 Not allowed!

  6. #6
      Junior
    L

    Registrado
    noviembre de 2015
    Mensajes
    33
    Ciudad
    Videla, Santa Fe

    Agradecimientos
     
    Recibidos
    18
    Enviados
    52

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    0

    Predeterminado PyAfipWs

    Hola, el PyAfipWs es posible implementarlo gratis. Está escrito en python, en la página (o el foro, ahora no recuerdo) tenés instrucciones paso a paso muy claras de como hacerlo, podés bajar el código fuente y generar el ejecutable. Y si se te complica implementarlo tenés la posibilidad de comprar el soporte técnico por un tiempo.
    Saludos

    Lascu

    0 Not allowed!

  7. #7
      Forero
    G

    Registrado
    febrero de 2015
    Edad
    67
    Mensajes
    180
    Ciudad
    Quilmes, Buenos Aires

    Agradecimientos
     
    Recibidos
    118
    Enviados
    89

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    19
    Concurso: Segundo puesto / Point Value: 0 Activista del Foro / Point Value: 0

    Predeterminado

    @Lascu, he seguido tu consejo y debo decir que pyafipws funciona de maravilla.

    Lo uso mediante el sistema de intercambio a traves de .TXT's.

    Es mucho mas veloz que la interfase que venía usando (any2fe - WSAFIPFE).

    Pero la mayor de las ventajas es que es gratis y sin licencias.

    Hace algunos dias implementé mi primer programa con esta interfase y todo va perfecto.

    Desde ya muchas gracias por el consejo.

    0 Not allowed!

  8. #8
      Guardián del Foro Avatar de Fito

    Registrado
    febrero de 2015
    Edad
    51
    Mensajes
    331
    Ciudad
    Córdoba, Villa María

    Agradecimientos
     
    Recibidos
    170
    Enviados
    176

    Citaciones y menciones
     
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Quoted
    0 Post(s)
    Poder de Reputación
    24
    Agradecimientos / Point Value: 0 Guardián del Foro / Point Value: 0 Activista del Foro / Point Value: 0

    Predeterminado

    Hola Amigos:

    Yo estoy usando esa ocx en power 8, no funciona como otro ocx que se pueda incorporar al formulario. Hay que instanciarlo en tiempo de ejecución. Acá les paso un ejemplo. Funciona de maravilla este ocx.

    COBOL Código:
    1. ENVIRONMENT     DIVISION.
    2.  DATA            DIVISION.
    3.  WORKING-STORAGE SECTION.
    4.  
    5.  77  oFactura                    pic x(8192) value "WSAFIPFE.factura"
    6.  77  FE object reference OLE.
    7.  01  SRC                         pic x(1024).
    8.  01  MSG                         pic x(1024).
    9.  
    10.  01  ii                          pic 9999.
    11.  
    12.  01  ind                         pic s9(5) comp-5.
    13.  
    14.  01  wcant-reg                   pic s9(9) comp-5.
    15.  01  redefines wcant-reg.
    16.      02 wcant-reg-x              pic x(9).
    17.          
    18. *... variables para usar con ocx
    19.  01  nModoFiscal                 pic s9(4) comp-5.
    20.  01  cCuit                       pic x(11).
    21.  01  redefines cCuit.
    22.      02 cCuit-n                  pic 9(11).
    23.  01  cArchivoCertificado         pic x(50).
    24.  01  cArchivoLicencia            pic x(50).
    25.  
    26.  01  iPuntoVenta                 pic s9(4) comp-5.
    27.  01  iComprobanteTipo            pic s9(4) comp-5.
    28.  01  iComprobanteFor             pic s9(9) comp-5.
    29.  
    30.  01  resultado                   pic x(200).
    31.  
    32.  01  variables-fe.
    33.      02 fe-error               pic s9(9) comp-5.
    34.  
    35.      02 fe-maecuit             pic x(11).
    36.      02 redefines fe-maecuit.
    37.         03 fe-maecuit-n        pic 9(11).
    38.      02 fe-certif              pic x(50).
    39.      02 fe-lic                 pic x(50).
    40.      02 fe-password            pic x(50) value "12345".
    41.      02 fe-valor-n             pic s9(9) comp-5.
    42.      02 fe-valor-c             pic x(25).
    43.      
    44.      02 fe-recibido.
    45.         03                     pic x(6) value "c:\rec".
    46.         03 fe-recibido-suc     pic 9999.
    47.         03                     pic xxxx  value ".xml".
    48.      02 fe-enviado.
    49.         03                     pic x(6) value "c:\env".
    50.         03 fe-enviado-suc      pic 9999.
    51.         03                     pic xxxx  value ".xml".
    52.      
    53.      02 fe-pv                  pic s9(4) comp-5.
    54.      02 fe-tipmov              pic s9(4) comp-5.
    55.      02 fe-concepto            pic s9(4) comp-5.
    56.      02 fe-cuittipo            pic s9(4) comp-5.
    57.      02 fe-cuit                pic x(11).
    58.      02 fe-for                 pic s9(9) comp-5.
    59.      02 fe-fec                 pic x(8).
    60.      02 fe-vto                 pic x(8).
    61.      02 fe-impo                comp-2.
    62.      02 fe-nogavado            comp-2.
    63.      02 fe-neto                comp-2.
    64.      02 fe-iva                 comp-2.
    65.      02 fe-tributos            comp-2.
    66.      02 fe-tributos-id         pic s9(9) comp-5.
    67.      02 fe-86base              comp-2.
    68.      02 fe-86alic              comp-2.
    69.      02 fe-86imp               comp-2.
    70.      02 fe-iibase              comp-2.
    71.      02 fe-iialic              comp-2.
    72.      02 fe-iiimp               comp-2.
    73.      02 fe-Munbase             comp-2.
    74.      02 fe-Munalic             comp-2.
    75.      02 fe-Munimp              comp-2.
    76.  
    77.      02 wrgMun                 pic x(50) value "Tasa Municipal".
    78.      02 wMunbase               pic 9(13)v99.
    79.      02 wMunalic               pic 9(13)v99.
    80.      02 wMunimp                pic 9(13)v99.
    81.  
    82.      02 wrg86                  pic x(50) value "Perc. Ing. Brutos".
    83.      02 w86base                pic 9(13)v99.
    84.      02 w86alic                pic 9(13)v99.
    85.      02 w86imp                 pic 9(13)v99.
    86.  
    87.      02 wimpint                pic x(50) value "Impuestos Internos".
    88.      02 wiibase                pic 9(13)v99.
    89.      02 wiialic                pic 9(13)v99.
    90.      02 wiiimp                 pic 9(13)v99.
    91.  
    92.      02 wtributos              pic 9(13)v99.
    93.      
    94.      02 wneto                  pic 9(13)v99.
    95.      02 wiva                   pic 9(13)v99.
    96.      
    97.      02 fe-indice              pic s9(4) comp-5.
    98.  
    99.      02 fe-cant-iva            pic s9(4) comp-5.
    100.  
    101.      02 fe-tabla-iva occurs 10 times.
    102.         03 fe-iva-id           pic s9(4) comp-5.
    103.         03 fe-iva-base         comp-2.
    104.         03 fe-iva-imp          comp-2.
    105.      
    106.      02 fe-cae                 pic x(20).
    107.      02 fe-caevto              pic x(8).
    108.  
    109.  01  xletra            pic x.
    110.      88 xletra-a       value "A".
    111.      88 xletra-b       value "B".
    112.      88 xletra-c       value "C""Copys\declara-com.cpy".
    113.  
    114.  proceso-obtener-cae.
    115.      move spaces                 to ffacae ffacaevto.
    116.  
    117.      move ffanum         to ccnum.
    118.      read ctacte invalid go sale.
    119.  
    120.      if fito-empiva = 1
    121.         if cctipoiva > 2
    122.            move "B"                 to xletra
    123.         else
    124.            move "A"                 to xletra
    125.         end-if
    126.      else
    127.         move "C"                    to xletra
    128.      end-if.   
    129.  
    130.      move ffarestipmov   to tpmcod.
    131.      read tipomov invalid go sale.
    132.  
    133.      move fito-empcuit           to cuit.
    134.      perform resuelve-cuit.
    135.      move ncuit                  to fe-maecuit-n.
    136.      move pfafacelec-cert        to fe-certif.
    137.      move pfafacelec-lic         to fe-lic.
    138.  
    139.      move ffasuc                 to fe-pv fe-recibido-suc fe-enviado-suc.
    140.      move tpmf532-comp           to fe-tipmov.
    141.      move 3                      to fe-concepto.
    142.      move cccuittipo             to fe-cuittipo.
    143.      move cccuit                 to cuit.
    144.      perform resuelve-cuit.
    145.      if ncuit = zeros move 1     to ncuit.
    146.      move ncuit                  to fe-cuit.
    147.  
    148.      move ffafec                 to fecha-inicial.
    149.      move ffavto                 to fecha-final.
    150.      perform fecha-can-dias.
    151.  
    152.      perform fecha-sistema.
    153.      move fecha-amd              to ffafec fe-fec.
    154.  
    155.      move ffafec                 to fecha-inicial.
    156.      perform fecha-suma-dias.
    157.      move fecha-final            to ffavto fe-vto.
    158.  
    159.      move ffaimpo                to fe-impo
    160.      move ffanograv              to fe-nogavado
    161.      if xletra-a
    162.         move ffaneto             to wneto
    163.         move ffaiva              to wiva
    164.      end-if.   
    165.      if xletra-b
    166.         compute wiva  = ffaimpiva(1) + ffaimpiva(2)
    167.         compute wneto = ffaneto - wiva
    168.      end-if.   
    169.      if xletra-c
    170.         move ffaneto             to wneto
    171.         move zeros               to wiva
    172.      end-if.   
    173.      
    174.      move wneto                  to fe-neto.
    175.      
    176.      if fito-empiva = 1
    177.         move wiva                   to fe-iva
    178.         move zeros                  to fe-cant-iva
    179.         perform varying w--ii from 1 by 1 until w--ii > 2
    180.            if ffaimpiva(w--ii) not = zeros
    181.               add 1                 to fe-cant-iva
    182.            end-if
    183.         end-perform
    184.         if fe-cant-iva = 1      *> si hay un solo iva lo hago con el neto por el tema redondeo
    185.            if ffaporiva(1) = 21
    186.               move 5             to fe-iva-id(1)
    187.            else   
    188.               move 4             to fe-iva-id(1)
    189.            end-if   
    190.            if xletra-a
    191.               move ffaneto       to fe-iva-base(1)
    192.               move ffaiva        to fe-iva-imp(1)
    193.            else   
    194.               compute fe-iva-base(1) rounded = ffaneto - ffaimpiva(1)
    195.               move ffaimpiva(1)     to fe-iva-imp(1)
    196.            end-if   
    197.         end-if   
    198.         if fe-cant-iva = 2
    199.            if ffaporiva(1) = 21
    200.               move 5             to fe-iva-id(1)
    201.            else   
    202.               move 4             to fe-iva-id(1)
    203.            end-if   
    204.            compute wneto rounded = ffaimpiva(1) / (ffaporiva(1) / 100)
    205.            move ffaimpiva(1)     to fe-iva-imp(1)
    206.            move wneto            to fe-iva-base(1)
    207.            if ffaporiva(2) = 21
    208.               move 5             to fe-iva-id(2)
    209.            else   
    210.               move 4             to fe-iva-id(2)
    211.            end-if   
    212.            compute wneto rounded = ffaimpiva(2) / (ffaporiva(2) / 100)
    213.            move ffaimpiva(2)     to fe-iva-imp(2)
    214.            move wneto            to fe-iva-base(2)
    215.         end-if   
    216.         if fe-cant-iva = zeros
    217.            move 1                to fe-cant-iva
    218.            move 3                to fe-iva-id(1)
    219.            move ffaneto          to fe-iva-base(1)
    220.            move zeros            to fe-iva-imp(1)
    221.         end-if   
    222.      else
    223.         move zeros               to fe-cant-iva
    224.         move zeros               to fe-iva
    225.      end-if.
    226.      
    227.      move zeros                  to wtributos.
    228.      
    229.      move zeros                  to w86base w86alic w86imp.
    230.      if ffaperiibb-imp not = zeros
    231.         move ffaperiibb-imp      to w86imp
    232.         move ffaperiibb-por      to w86alic
    233.         compute w86base rounded = w86imp * 100 / w86alic
    234.         add  w86imp              to wtributos
    235.      end-if.
    236.      move w86base                to fe-86base.
    237.      move w86alic                to fe-86alic.
    238.      move w86imp                 to fe-86imp.
    239.  
    240.      move zeros                  to wiibase wiialic wiiimp.
    241.      if ffagasoil-itc not = zeros
    242.         add ffagasoil-itc        to wiiimp
    243.         move zeros               to wiialic
    244.         move ffaneto             to wiibase
    245.         add ffagasoil-itc        to wtributos
    246.      end-if.
    247.      if ffagasoil-imp not = zeros
    248.         add ffagasoil-imp        to wiiimp
    249.         move zeros               to wiialic
    250.         move ffaneto             to wiibase
    251.         add ffagasoil-imp        to wtributos
    252.      end-if.
    253.      move wiibase                to fe-iibase.
    254.      move wiialic                to fe-iialic.
    255.      move wiiimp                 to fe-iiimp.
    256.  
    257.      move zeros                  to wMunbase wMunalic wMunimp.
    258.      if ffaimpmuni not = zeros
    259.         move ffaimpmuni          to wMunimp
    260.         move ffapormuni          to wMunalic
    261.         if wMunalic not = zeros
    262.            compute wMunbase rounded = wMunimp * 100 / wMunalic
    263.         else
    264.            move zeros            to wMunbase
    265.         end-if     
    266.         add  wMunimp             to wtributos
    267.      end-if.
    268.      move wMunbase               to fe-Munbase.
    269.      move wMunalic               to fe-Munalic.
    270.      move wMunimp                to fe-Munimp.
    271.  
    272.      move wtributos              to fe-tributos.
    273.      
    274.      if pfafacelec-lic = spaces
    275.         move zeros               to nModoFiscal
    276.      else   
    277.         move 1                   to nModoFiscal
    278.      end-if.   
    279.      move fe-maecuit             to cCuit.
    280.      move fe-certif              to cArchivoCertificado.
    281.      move fe-lic                 to cArchivoLicencia.
    282.      
    283.      if nModoFiscal = zeros
    284.         invoke grdLista "AddItem" using "WebService de PRUEBA"
    285.      else   
    286.         invoke grdLista "AddItem" using "WebService de PRODUCCION"
    287.      end-if.   
    288.      invoke grdLista "AddItem" using cCuit.
    289.      invoke grdLista "AddItem" using cArchivoCertificado.
    290.      invoke grdLista "AddItem" using cArchivoLicencia.
    291.      invoke grdLista "AddItem" using fe-recibido.
    292.      invoke grdLista "AddItem" using fe-enviado.
    293.      perform refresca.
    294.      
    295.      invoke OLE "CREATE-OBJECT" using oFactura returning FE.
    296.      
    297.      invoke FE "iniciar" using nModoFiscal cCuit cArchivoCertificado cArchivoLicencia returning fe-error.
    298.      invoke FE "SET-ArchivoCertificadoPassWord" using fe-password.
    299.      
    300.      if fe-error = pow-true
    301.         perform restaurar-tique
    302.         invoke FE "f1TicketEsValido" returning fe-error
    303.         if fe-error = pow-false
    304.            invoke FE "f1ObtenerTicketAcceso" returning fe-error
    305.            invoke grdLista "AddItem" using "Genera Nuevo Tique"
    306.         else
    307.            invoke grdLista "AddItem" using "El tique es Válido"
    308.         end-if   
    309.         if fe-error = pow-true
    310.            perform guardar-tique
    311.            move fe-pv            to iPuntoVenta
    312.            move fe-tipmov        to iComprobanteTipo
    313.            invoke FE "f1CompUltimoAutorizado" using iPuntoVenta iComprobanteTipo RETURNING iComprobanteFor
    314.            compute fe-for = iComprobanteFor + 1
    315.  
    316.            move "Formulario"     to llite2
    317.            move fe-for           to lnro2
    318.            invoke grdLista "AddItem" using muestra2
    319.  
    320.            move 1                to fe-valor-n
    321.            invoke FE "SET-F1CabeceraCantReg"     using fe-valor-n
    322.            invoke FE "SET-F1CabeceraPtoVta"      using fe-pv 
    323.            invoke FE "SET-F1CabeceraCbteTipo"    using fe-tipmov
    324.            invoke FE "SET-F1DetalleConcepto"     using fe-concepto
    325.            invoke FE "SET-F1DetalleDocTipo"      using fe-cuittipo
    326.            invoke FE "SET-F1DetalleDocNro"       using fe-cuit
    327.            invoke FE "SET-F1DetalleCbteDesde"    using fe-for
    328.            invoke FE "SET-F1DetalleCbteHasta"    using fe-for
    329.            invoke FE "SET-F1DetalleCbteFch"      using fe-fec
    330.            invoke FE "SET-F1DetalleImpTotal"     using fe-impo
    331.            invoke FE "SET-F1DetalleImpTotalConc" using fe-nogavado
    332.            invoke FE "SET-F1DetalleImpNeto"      using fe-neto
    333.            invoke FE "SET-F1DetalleImpIva"       using fe-iva
    334.            invoke FE "SET-F1DetalleImpTrib"      using fe-tributos
    335.  
    336.            invoke FE "SET-F1DetalleFchServDesde" using fe-fec
    337.            invoke FE "SET-F1DetalleFchServHasta" using fe-fec
    338.            invoke FE "SET-F1DetalleFchVtoPago"   using fe-vto
    339.            move "PES"            to fe-valor-c
    340.            invoke FE "SET-F1DetalleMonId"        using fe-valor-c
    341.            move 1                to fe-valor-n
    342.            invoke FE "SET-F1DetalleMonCotiz"     using fe-valor-n
    343.  
    344.            move "Neto"           to llite
    345.            move fe-neto          to limpo
    346.            invoke grdLista "AddItem" using muestra
    347.            move "IVA"            to llite
    348.            move fe-iva           to limpo
    349.            invoke grdLista "AddItem" using muestra
    350.            move "TOTAL"          to llite
    351.            move fe-impo          to limpo
    352.            invoke grdLista "AddItem" using muestra
    353.            perform refresca
    354.      
    355.            move zeros               to w--ii     
    356.            if ffaperiibb-imp not = zeros           
    357.               add 1                 to w--ii
    358.               move w--ii            to fe-valor-n
    359.               invoke FE "SET-F1DetalleTributoItemCantidad" using fe-valor-n
    360.               compute fe-indice = w--ii - 1
    361.               invoke FE "SET-f1IndiceItem"              using fe-indice
    362.               move 2                to fe-tributos-id
    363.               invoke FE "SET-F1DetalleTributoId"        using fe-tributos-id
    364.               invoke FE "SET-F1DetalleTributoDesc"      using wrg86
    365.               invoke FE "SET-F1DetalleTributoBaseImp"   using fe-86base
    366.               invoke FE "SET-F1DetalleTributoAlic"      using fe-86alic
    367.               invoke FE "SET-F1DetalleTributoImporte"   using fe-86imp
    368.               move "PER IIBB Base"  to llite
    369.               move fe-86base        to limpo
    370.               invoke grdLista "AddItem" using muestra
    371.               move "PER IIBB ALic."   to llite
    372.               move fe-86alic        to limpo
    373.               invoke grdLista "AddItem" using muestra
    374.               move "PER IIBB Imp."    to llite
    375.               move fe-86imp         to limpo
    376.               invoke grdLista "AddItem" using muestra
    377.            end-if
    378.            if ffagasoil-itc not = zeros or
    379.               ffagasoil-imp not = zeros
    380.               add 1                 to w--ii
    381.               move w--ii            to fe-valor-n
    382.               invoke FE "SET-F1DetalleTributoItemCantidad" using fe-valor-n
    383.               compute fe-indice = w--ii - 1
    384.               invoke FE "SET-f1IndiceItem"              using fe-indice
    385.               move 4                to fe-tributos-id
    386.               invoke FE "SET-F1DetalleTributoId"        using fe-tributos-id
    387.               invoke FE "SET-F1DetalleTributoDesc"      using wimpint
    388.               invoke FE "SET-F1DetalleTributoBaseImp"   using fe-iibase
    389.               invoke FE "SET-F1DetalleTributoAlic"      using fe-iialic
    390.               invoke FE "SET-F1DetalleTributoImporte"   using fe-iiimp
    391.               move "Imp.Int. Base"  to llite
    392.               move fe-iibase        to limpo
    393.               invoke grdLista "AddItem" using muestra
    394.               move "Imp.Int. ALic." to llite
    395.               move fe-iialic        to limpo
    396.               invoke grdLista "AddItem" using muestra
    397.               move "Imp.Int. Imp."  to llite
    398.               move fe-iiimp         to limpo
    399.               invoke grdLista "AddItem" using muestra
    400.            end-if
    401.            if ffaimpmuni not = zeros           
    402.               add 1                 to w--ii
    403.               move w--ii            to fe-valor-n
    404.               invoke FE "SET-F1DetalleTributoItemCantidad" using fe-valor-n
    405.               move zeros            to fe-indice           
    406.               invoke FE "SET-f1IndiceItem"              using fe-indice
    407.               move 3                to fe-valor-n
    408.               invoke FE "SET-F1DetalleTributoId"        using fe-valor-n
    409.               invoke FE "SET-F1DetalleTributoDesc"      using wrgMun
    410.               invoke FE "SET-F1DetalleTributoBaseImp"   using fe-Munbase
    411.               invoke FE "SET-F1DetalleTributoAlic"      using fe-Munalic
    412.               invoke FE "SET-F1DetalleTributoImporte"   using fe-Munimp
    413.               move "Imp.Mun. Base"  to llite
    414.               move fe-Munbase       to limpo
    415.               invoke grdLista "AddItem" using muestra
    416.               move "Imp.Mun. ALic." to llite
    417.               move fe-Munalic       to limpo
    418.               invoke grdLista "AddItem" using muestra
    419.               move "Imp.Mun. Imp."  to llite
    420.               move fe-Munimp        to limpo
    421.               invoke grdLista "AddItem" using muestra
    422.            end-if
    423.                      
    424.            invoke FE "SET-F1DetalleIvaItemCantidad" using fe-cant-iva
    425.            perform varying w--ii from 1 by 1 until w--ii > fe-cant-iva
    426.               compute fe-indice = w--ii - 1
    427.               invoke FE "SET-f1IndiceItem"        using fe-indice
    428.               invoke FE "SET-F1DetalleIvaId"      using fe-iva-id(w--ii)
    429.               invoke FE "SET-F1DetalleIvaBaseImp" using fe-iva-base(w--ii)
    430.               invoke FE "SET-F1DetalleIvaImporte" using fe-iva-imp(w--ii)
    431.            end-perform
    432.            
    433.            move zeros        to fe-valor-n
    434.            invoke FE "SET-F1DetalleCbtesAsocItemCantidad" using fe-valor-n
    435.            invoke FE "SET-F1DetalleOpcionalItemCantidad"  using fe-valor-n
    436.            
    437.            move fe-recibido  to fe-valor-c
    438.            invoke FE "SET-ArchivoXMLRecibido" using fe-valor-c
    439.            move fe-enviado   to fe-valor-c
    440.            invoke FE "SET-ArchivoXMLEnviado"  using fe-valor-c
    441.  
    442.            invoke FE "f1CAESolicitar"
    443.            
    444.            invoke FE "F1RespuestaResultado" returning Resultado
    445.            if Resultado = "A"
    446.               invoke FE "F1RespuestaDetalleCae" returning Resultado
    447.               move resultado                     to fe-cae
    448.               invoke FE "f1RespuestaDetalleCAEFchVto" returning Resultado
    449.               move resultado                     to fe-caevto
    450.               move fe-for        to ffaresfor
    451.               move fe-cae        to ffacae
    452.               move fe-caevto     to ffacaevto
    453.               move 1             to ffaimpreso
    454.               move fe-fec        to ffafec
    455.               rewrite regffa
    456.               invoke grdLista "AddItem" using "ACEPTADO - CAE N°"
    457.               invoke grdLista "AddItem" using fe-cae
    458.            else   
    459.               invoke grdLista "AddItem" using "RECHAZADO" returning ind
    460.               move pow-color-red        to "ListBackColor"(ind) of grdLista
    461.            end-if   
    462.            invoke FE "f1RespuestaDetalleObservacionItemCantidad" returning fe-error
    463.            if fe-error not = zeros
    464.               perform varying w--ii from 1 by 1 until w--ii > fe-error
    465.                  compute fe-indice = w--ii - 1
    466.                  invoke FE "f1RespuestaDetalleObservacionMsg" returning Resultado
    467.                  invoke grdLista "AddItem" using Resultado returning ind
    468.                  move pow-color-green   to "ListBackColor"(ind) of grdLista
    469.               end-perform
    470.            end-if     
    471.         else
    472.            invoke grdLista "AddItem" using "Fallo Acceso WebService AFIP"
    473.            invoke FE "UltimoMensajeError" returning Resultado
    474.            invoke grdLista "AddItem" using Resultado
    475.         end-if
    476.      else   
    477.         invoke grdLista "AddItem" using "Fallo Iniciando WebService AFIP"
    478.         invoke FE "UltimoMensajeError" returning Resultado
    479.         invoke grdLista "AddItem""Copys\comunpro.cpy".
    480.  
    481.  guardar-tique.
    482.      open i-o fe-tique.
    483.      move fe-maecuit-n      to fe-tique-cuit.
    484.      read fe-tique invalid initialize fe-tique-campos.
    485.      invoke FE "f1GuardarTicketAcceso" returning fe-tique-token.
    486.      write regfe-tique invalid rewrite regfe-tique.
    487.      close fe-tique.
    488.  
    489.  restaurar-tique.
    490.      open input fe-tique.
    491.      move fe-maecuit-n      to fe-tique-cuit.
    492.      read fe-tique not invalid
    493.         invoke FE "f1RestaurarTicketAcceso" using fe-tique-token
    494.      end-read.
    495.      close fe-tique.

    En el REPOSITORY del formulario tienen que declarar...
    COBOL Código:
    1.      CLASS OLE AS "*OLE"
    2.      CLASS EXCEP AS "*COM-EXCEPTION"

    Disculpen que le pasé la rutina completa, pero vayan sacando lo que necesitan de ahí...

    Saludos.

    Fito...

    0 Not allowed!

Información de Tema

Usuarios Viendo este Tema

Actualmente hay 1 usuarios viendo este tema. (0 miembros y 1 visitantes)

Temas Similares

  1. [Componente] Factura Electronica Argentina
    Por JulioBenitez9470 en el foro PowerCOBOL (ActiveX, v4 - v11)
    Respuestas: 23
    Último Mensaje: 16.09.2021, 15:57

User Tag List

Permisos de Publicación

  • No puedes crear nuevos temas
  • No puedes responder temas
  • No puedes subir archivos adjuntos
  • No puedes editar tus mensajes
  •