[Sintaxis] Formatear Fecha

[dariodr]

Buenas comunidad, tengo este codigo (es simple) lo que quiero es formatear la fecha al formato YY/MM/DD con las barras de separacion y no me sale, que hago mal.
Saludos.

       IDENTIFICATION DIVISION.
       PROGRAM-ID. YOUR-PROGRAM-NAME.
       DATA DIVISION.
       FILE SECTION.
       WORKING-STORAGE SECTION.
       01  HOY        PIC 9(6).
       01  FECHA-HOY.
           03 ANIO    PIC 99.
           03 FILLER  PIC X VALUE '/'.
           03 MES     PIC 99.
           03 FILLER  PIC X VALUE '/'.
           03 DIA     PIC 99.
       PROCEDURE DIVISION.
       MAIN-PROCEDURE.
            DISPLAY "Fecha: ".
            ACCEPT HOY FROM DATE.
            MOVE HOY TO FECHA-HOY.
            DISPLAY FECHA-HOY.
            STOP RUN.
       END PROGRAM YOUR-PROGRAM-NAME.

[fastpho]

Hola @dariodr

 WORKING-STORAGE SECTION.    
 01  HOY.
      03 Hoy-Anio   PIC 99.
      03 Hoy-Mes   PIC 99.
      03 Hoy-Dia    PIc 99.
 
 01  FECHA-HOY.
     03 ANIO    PIC 99.
     03 FILLER  PIC X VALUE '/'.
     03 MES     PIC 99.
     03 FILLER  PIC X VALUE '/'.
     03 DIA     PIC 99.   
 PROCEDURE DIVISION.
            ACCEPT HOY FROM DATE.
            *>MOVE HOY TO FECHA-HOY.
            MOVE Hoy-Anio TO ANIO
            MOVE Hoy-Mes  TO MES
            MOVE Hoy-Dia  TO DIA
            DISPLAY FECHA-HOY. 

Saludos ....

[JCantero]

@dariodr, cuestión de gustos, pero a mi e gusta hacerlo así:

         string hoy(1:2) '/' hoy(3:2) '/' hoy(5:2) delimited by size into fecha-hoy

y si quieres ponerla en formato dd/mm/aa

         string hoy(5:2) '/' hoy(3:2) '/' hoy(1:2) delimited by size into fecha-hoy

[Fito]

Hola:

Tambien lo podés hacer de esta manera

 
       WORKING-STORAGE SECTION.
       01  HOY           PIC 9(6).
       01  FECHA-HOY     pic 99/99/99.
 
       PROCEDURE DIVISION.
 
       MAIN-PROCEDURE.
            ACCEPT HOY FROM DATE.
            MOVE HOY TO FECHA-HOY.
            DISPLAY FECHA-HOY.
            STOP RUN.

[Josber]

Yo soy más clásico

01  FECHA.
      03  AA                 PIC 99.
      03  MM                PIC 99.
      03  DD                 PIC 99.
 
01  FECHA-EDI.
      03  DD                 PIC 99.
      03  FILLER           PIC X VALUE "/".
      03  MM                PIC 99.
      03  FILLER           PIC X VALUE "/".
      03  AA                 PIC 99.
.
.
.
 
      ACCEPT FECHA FROM DATE.
      MOVE CORRESPONDING FECHA TO FECHA-EDI.

Lo pongo porque, veo que en el foro, se ha comentado o se ha puesto muy pocas veces algo usando el verbo CORR ó CORRESPONDING y, es más útil de lo que parece.
Un saludo a todos.