SQlite3 con PowerCobol

fastpho · 21.08.2026 18:08

Permite integrar el motor de base de datos de SQlite con nuestras aplicaciones.
En mi caso es para poder interactuar con una aplicacion que hice para Android
y poder leer la informacion de la BD y evitar utilizar archivos con formato .CSV
como interface.
Su implementacion es muy sencilla descargar Binarios precompilados
para Windows para su version 32 bits (sqlite3.dll) no hace falta registrarla.

1 - Copiar Sqlite3.dll en la carpeta del proyecto
2 - Agregar la funciones de la libreria en el Archivo COBOL85
3 - Luego llamar a esas funciones via call
4 - Informacion de las funciones en : https://sqlite.org/c3ref/funclist.html

Ejemplo para abrir , crear , insertar , actualizar un registro y cerrar

Declaracion Variables

Código COBOL:

 01  BD-HANDLE                      PIC 9(9) COMP-5  IS GLOBAL. *>Handle de la BD
 01  BD-FILE-NAME                   PIC X(50)        IS GLOBAL. *>Nombre de la BD
 01  BD-SQL-QUERY                   PIC X(256)       IS GLOBAL. *>string sql (Create , Insert , Delete , Update , Select)
 01  BD-SQL-STRING-LENGHT           PIC S9(9) COMP-5 IS GLOBAL.
 01  BD-HANDLE-STMT                 PIC 9(9) COMP-5  IS GLOBAL.  *>Puntero Statement
 01  BD-STMT-PTR REDEFINES BD-HANDLE-STMT POINTER    IS GLOBAL.  *>Redefines del Puntero Statement
 
 01  BD-INT-POINTER                 POINTER          IS GLOBAL.
 01  BD-INT                         PIC 9(9) COMP-5  IS GLOBAL. *> INTEGER
 01  BD-DOB                         PIC 9(9) COMP-5  IS GLOBAL. *> DOUBLE 
 
 01  BD-TEXT-POINTER                POINTER          IS GLOBAL.
 01  BD-TEXT                        PIC X(256)       IS GLOBAL. *> TEXT 
 01  BD-SQL-ERROR                   POINTER          IS GLOBAL.
 
 
 01  BD-FILA-ID                     PIC 9(9) COMP-5  IS GLOBAL.
 01  BD-COLUMNA-CANTIDAD            PIC 9(9) COMP-5  IS GLOBAL.
 01  BD-COLUMNA-NUMERO              PIC 9(9) COMP-5  IS GLOBAL. 
 01  BD-COLUMNA-NOMBRE              PIC X(256)       IS GLOBAL.
 01  BD-COLUMNA-POINTER             POINTER          IS GLOBAL.
 
 
* Estado de la Base de Datos
 01  BD-STATUS                      PIC 9(9) COMP-5  IS GLOBAL. 
 *>Estado de la BD
 01  ESTADOS-BD IS GLOBAL.
     03 SQLITE_OK       PIC 9(9) COMP-5  VALUE 0.   *> /* Successful result */
     03 SQLITE_ERROR    PIC 9(9) COMP-5  VALUE 1.   *> /* Generic error */
     03 SQLITE_BUSY     PIC 9(9) COMP-5  VALUE 5.   *> /* The database file is locked */
     03 SQLITE_LOCKED   PIC 9(9) COMP-5  VALUE 6.   *> /*  A table in the database is locked */
     03 SQLITE_READONLY PIC 9(9) COMP-5  VALUE 8.   *> /*  Attempt to write a readonly database */
     03 SQLITE_EMPTY    PIC 9(9) COMP-5  VALUE 16.  *> /*  Attempt to write a readonly database */
     
     
     03 SQLITE_MISUSE   PIC 9(9) COMP-5  VALUE 21.  *> /* Library used incorrectly */
     03 SQLITE_WARNING  PIC 9(9) COMP-5  VALUE 28.  *> /* unusual and possibly ill-advised operation is taking place.*/
     
     03 SQLITE-ROW      PIC 9(9) COMP-5  VALUE 100. *> /* sqlite3_step() has another row ready */ 
     03 SQLITE-DONE     PIC 9(9) COMP-5  VALUE 101. *> /* sqlite3_step() has finished executing */
* Tipos de Datos sqlite     
 01  BD-COLUMNA-TIPO       PIC 9(4) COMP-5 IS GLOBAL.
      88  SQL-INTEGER        VALUE 1. *> 
      88  SQL-REAL           VALUE 2. *>  
      88  SQL-TEXT           VALUE 3. *> 
      88  SQL-BLOB           VALUE 4. *> 
      88  SQL-NULL           VALUE 5. *> 
     
 
 01 FECHA-CONVERTIR       PIC 9(8)         IS GLOBAL. *> AAAAMMDD a Convertir 
 01 FECHA-CONVERTIDA-UNIX PIC 9(13)        IS GLOBAL. *> Fecha con formato unix
 01 FECHA-UNIX1970        PIC S9(9) COMP-5 IS GLOBAL. *> desde AAAAMMDDD 19700101
 01 FECHA-INT             PIC S9(9) COMP-5 IS GLOBAL. 
 01 FECHA-AMD             PIC 9(8)         IS GLOBAL.
 01 FECHA-AMD-ED          PIC XXXX/XX/XX   IS GLOBAL.
 
 01 NULO                           PIC 9(9)  COMP-5 VALUE 0 IS GLOBAL.    *> NULO
 
 *>[url]https://sqlite.org/cintro.html[/url]
 *>Funciones de la libreria sqlit3.dll
 *>[url]https://sqlite.org/c3ref/funclist.html[/url]
 *>Funciones Declaradas en el archivo COBOL85.CBR
 *>Fecha 17-04-2023
 01  FUNCIONES-SQLITE3-LIB          PIC X(50)        IS GLOBAL. 
*> sqlite3-connection functions
    *>  sqlite3_libversion (OUT <text>)                                                  *> Devuelve la versión de sqlite a través del parámetro OUT. OK probado
    *>  sqlite3_libversion_number (OUT <int>                   )                         *> Devuelve el número de versión como un int  OK probado
    *>  sqlite3_open       (<nombre de archivo>, OUT <controlador de la base de datos>). *> Esto abre un archivo de base de datos SQLite , nueva o existente como se especifica en el argumento de nombre de archivo.OK probado
    *>  sqlite3_close       (<db-handle>)(<identificador de la base de datos>)           *> Destructor de la interface , cierra la BD OK probado
    *>  sqlite3_exec       (<gestor-bd>,<cadena-sql>)                                    *> Es una envoltura  sqlite3_prepare_v2(), sqlite3_step() y sqlite3_finalize() OK probado
    *>  sqlite3_errmsg     (<db-handle>, OUT <mensaje de error)                          *> Devuelve texto en inglés como un parámetro OUT que describe el último error en la conexión. OK probado
 
*> sqlit3-statement functions    
   *> sqlite3_prepare_v2  *>Constructor OK probado
   *> sqlite3_finalize    *>Destructor  OK probado
      *> Pass
         *> sqlite3_step         int sqlite3_step(sqlite3_stmt*);  OK probado 
         *> sqlite3_reset        int sqlite3_reset(sqlite3_stmt *pStmt); OK probado
         *> sqlite3_finalize     int sqlite3_finalize(sqlite3_stmt *pStmt); OK probado
         
      *> Statement column access (0-base indices) 
         *> sqlite3_column_count    int sqlite3_column_count(sqlite3_stmt *pStmt);   OK probado 
         *> sqlite3_column_type     int sqlite3_column_type(sqlite3_stmt*, int iCol);  OK probado
         *> sqlite3_column_name     const char *sqlite3_column_name(sqlite3_stmt*, int N); OK probado
      *> Statement column type 
         *> sqlite3_column_int      int sqlite3_column_int(sqlite3_stmt*, int iCol);  OK probado
         *> sqlite3_column_text     const unsigned char *sqlite3_column_text(sqlite3_stmt*, int iCol);   OK probado
         *> sqlite3_column_double   double sqlite3_column_double(sqlite3_stmt*, int iCol);   OK probado
         *> sqlite3_column_blob     no implementado

Abrir BD

Código COBOL:

*------------------------------------------------------------------     
*>sqlite3_open
*    DISPLAY "------------".
*    DISPLAY "sqlite3_open". 
 
     MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
     MOVE "sqlite3_open"         TO FUNCIONES-SQLITE3-LIB.    
     MOVE "datos.db"  & X"00"    TO BD-FILE-NAME.
     
     call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
              USING BY REFERENCE BD-FILE-NAME
                    BY REFERENCE BD-HANDLE 
             returning  BD-STATUS
 
     end-call.
     IF BD-STATUS  NOT = SQLITE_OK THEN
        CALL "BD-ERROR"
     ELSE
        MOVE  "OK" TO "Caption" OF CmStatic2
     END-IF.

Crear BD

Código COBOL:

*------------------------------------------------------------------     
*>sqlite3_exec
*    DISPLAY "------------".
*    DISPLAY "sqlite3_exec". 
*    DISPLAY "CREATE". 
     MOVE SPACES                 TO BD-SQL-QUERY.
     MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
     MOVE "sqlite3_exec"         TO FUNCIONES-SQLITE3-LIB.    
     MOVE "CREATE TABLE usuarios (id INTEGER PRIMARY KEY AUTOINCREMENT  , nombre TEXT , edad INTEGER )" & X"00" TO BD-SQL-QUERY.
 
     call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
              USING 
                    BY VALUE   BD-HANDLE
                    BY CONTENT BD-SQL-QUERY
              BY VALUE 0
              BY VALUE 0
              BY VALUE 0
             returning  BD-STATUS
 
     end-call.
     
 
     IF BD-STATUS NOT = SQLITE_OK THEN
        CALL "BD-ERROR"
     ELSE 
        MOVE "OK" TO "Caption" OF CmStatic2
     END-IF.

Insertar Registro BD

Código COBOL:

*------------------------------------------------------------------     
*>sqlite3_exec
*    DISPLAY "------------------".
*    DISPLAY "sqlite3_exec". 
*    DISPLAY "INSERT". 
 
     MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
     MOVE "sqlite3_exec"         TO FUNCIONES-SQLITE3-LIB.    
 
     MOVE SPACES                 TO BD-SQL-QUERY.    
     string "INSERT INTO usuarios (nombre , edad ) " delimited by size  
            " VALUES ('Leonardo' , 24 )" delimited by size 
            x"00" delimited by size
            into BD-SQL-QUERY
     end-string.
 
     
     call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
              USING 
                    BY VALUE   BD-HANDLE
                    BY CONTENT BD-SQL-QUERY
              BY VALUE 0
              BY VALUE 0
              BY VALUE 0
             returning  BD-STATUS
 
     end-call.
     IF BD-STATUS NOT = SQLITE_OK 
        CALL "BD-ERROR"
     END-IF.

Actualizar Registro BD

Código COBOL:

 PROCEDURE       DIVISION.
*------------------------------------------------------------------     
*>sqlite3_exec
*    DISPLAY "------------------".
*    DISPLAY "sqlite3_exec". 
*    DISPLAY "UPDATE". 
 
     MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
     MOVE SPACES                 TO BD-SQL-QUERY.         
     MOVE "sqlite3_exec"         TO FUNCIONES-SQLITE3-LIB.
 
 
     string "UPDATE usuarios SET  nombre = 'xxxx' " delimited by size  
            "  WHERE id = 1" delimited by size 
            x"00" delimited by size
            into BD-SQL-QUERY
     end-string.
 
     
     call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
              USING 
                    BY VALUE   BD-HANDLE
                    BY CONTENT BD-SQL-QUERY
              BY VALUE 0
              BY VALUE 0
              BY VALUE 0
             returning  BD-STATUS
 
     end-call.
     
     IF BD-STATUS NOT = SQLITE_OK 
        CALL "BD-ERROR"
     ELSE
        MOVE  "OK" TO "Caption" OF CmStatic2
     END-IF.

Cerar BD

Código COBOL:

*------------------------------------------------------------------     
*>sqlite3_close
*    DISPLAY "------------".
*    DISPLAY "sqlite3_close". 
 
     MOVE SPACES                 TO FUNCIONES-SQLITE3-LIB.
     MOVE "sqlite3_close"        TO FUNCIONES-SQLITE3-LIB.    
 
     call     FUNCIONES-SQLITE3-LIB WITH  STDCALL  LINKAGE
              USING     BY VALUE BD-HANDLE
             returning  BD-STATUS
 
     end-call.
 
     IF BD-STATUS NOT = SQLITE_OK THEN
        CALL "BD-ERROR"
     ELSE
        MOVE  "OK" TO "Caption" OF CmStatic2        
     END-IF.

Saludos....

Joseg · 17.09.2026 18:23

Muito interessante!
Obrigado

Josber · 20.09.2026 12:17

Gracias @fastpho, lo único que recomiendo encarecidamente cuando se trabaja con BDs, es que los nombre de las variables que usemos para esas BDs, no contengan el guion medio (-), y sí el guion bajo (_), esto es porque sql, lo puede confundir con el signo de restar (-), el programa puede hacer cosas inesperadas y te vuelves loco buscando el error, (por experiencia propia). Aquí, no parece que se vaya a dar la condición, pero, no es malo, coger esa costumbre. Sólo hay que fijarse en las variables propias de sql, en las que todas son SQLITE_xxxx, y no SQLITE-xxxx

Por lo demás, un excelente aporte

Un salu2.-

fastpho · 21.08.2026 18:08

Gracias @Josber , voy a tomar la sugerencia para evitar posibles problemas
Saludos....

luisbago · 20.09.2026 07:34

un idx2sqlite seria fabuloso, así se traslada datos sin intermediarios

Joseg · 17.09.2026 18:23

Citación del post de fastpho

❞

Gracias @Josber , voy a tomar la sugerencia para evitar posibles problemas
Saludos....

O mesmo exemplo, mas usando o Sqlit3.Lib. Não necessita de cobol85.cbr

Para criar o .LIB na mesma pasta a onde esta o SQLITE3.DLL
Linha de comandos: lib /DEF:sqlite3.def /OUT:sqlite3.lib /MACHINE:x32 (ou x64)

Joseg · 17.09.2026 18:23

Hola,

Como implementar un loop en PowerCobol?

Ejemplo de lista de todos los registros de "MyTable":

Código SQL:

SELECT * FROM MyTable

Creo que tienes que usar "sqlite3_prepare" y "sqlite3_step", o implementar una "devolución de llamada" (callback),

Código COBOL:

01 CALLBACK USAGE PROCEDURE-POINTER.

... pero no lo estoy consiguiendo.

Gracias,
Jose

fastpho · 21.08.2026 18:08

Hola @Joseg

Para poder realizar un "select" yo no lo pude hacer por "CALLBACK"
trabajo con la version 5.0 de PowerCobol y no acepta PROCEDURE-POINTER
Entonces para resolverlo hago :

sqlite3_open_v2
sqlite3_prepare_v2

sqlite3_step aca hay que meter el loop si

Código:

SQLITE_ROW

o

Código:

SQLITE_DONE

sqlite3_finalize
sqlite3_close_v2
Saludos...

Joseg · 17.09.2026 18:23

Citación del post de fastpho

❞

Hola @Joseg

Para poder realizar un "select" yo no lo pude hacer por "CALLBACK"
trabajo con la version 5.0 de PowerCobol y no acepta PROCEDURE-POINTER
Entonces para resolverlo hago :

sqlite3_open_v2
sqlite3_prepare_v2

sqlite3_step aca hay que meter el loop si

Código:

SQLITE_ROW

o

Código:

SQLITE_DONE

sqlite3_finalize
sqlite3_close_v2
Saludos...

Muchas gracias

Pero, sigue sin funcionar

Código COBOL:

 working-storage.
 01  num-bytes                      pic s9(09) COMP-5  IS GLOBAL.
 01  num-columns                    pic s9(09) COMP-5  IS GLOBAL.
 01  pStmt                          usage pointer      IS GLOBAL.
 01  zTail                          pic s9(09) COMP-5  IS GLOBAL.
 
 procedure division.
 
     MOVE "chinook.db"  & X"00"  TO BD-FILE-NAME.
     
     call "sqlite3_open_v2"  & X"00"  WITH  STDCALL  LINKAGE
              USING BY REFERENCE BD-FILE-NAME
                    BY REFERENCE BD-HANDLE 
                    BY VALUE 2  *> SQLITE_OPEN_READWRITE
                    BY VALUE 0
             returning  BD-STATUS
 
     end-call.
 
     string "SELECT * from artists WHERE name='Body Count' " delimited by size  
            X"00" delimited by size
            into BD-SQL-QUERY
            WITH POINTER num-bytes.
 
     move zero to zTail
       
     call  "sqlite3_prepare_v2"  & X"00" WITH  STDCALL  LINKAGE
              USING 
                    BY VALUE     BD-HANDLE
                    BY CONTENT   BD-SQL-QUERY
                    BY VALUE     num-bytes
                    by reference pStmt
                    by VALUE     zTail
             returning  BD-STATUS
 
     end-call.    
 
*loop
     call "sqlite3_step"  & X"00" WITH  STDCALL  LINKAGE
           using 
               by reference pStmt
           returning BD-STATUS
     end-call.
 
    evaluate ESTADOS-BD
       when SQLITE-ROW
           display "SQLITE-ROW"
       when SQLITE-DONE
           display "SQLITE-DONE"
    end-evaluate

¿Qué tiene de malo esta parte del código?
call "sqlite3_step" da el error
SQLITE_MISUSE = 21. *> Library used incorrectly

Powercobol v9
Gracias,
José

fastpho · 21.08.2026 18:08

@Joseg
La funcion sqlite3_step espera el valor por value no por reference seria asi :

Código COBOL:

working-storage.
01 stmt-handle   PIC 9(9) COMP-5.
01 redefines stmt-handle.
    05  pStmt usage pointer.

Código COBOL:

     call "sqlite3_step"  & X"00" WITH  STDCALL  LINKAGE
           using  by value stmt-handle
           returning BD-STATUS
     end-call

Saludos...

Otros temas que te pueden interesar
Tema	Autor	Foro	Respuestas	Último post
[Sintaxis] SQL embebido - cursor con COUNT() en PowerCOBOL 7	drvedia1981	PowerCOBOL (ActiveX, v4 - v11)	13	7 de junio de 2023 11:28
Microsoft ADO con PowerCobol	fastpho	PowerCOBOL (ActiveX, v4 - v11)	0	27 de abril de 2022 18:47
[Sintaxis] Compratir variable con un EXE de PowerCOBOL	Recato53	PowerCOBOL (ActiveX, v4 - v11)	10	14 de febrero de 2017 17:18
[Duda] PowerCOBOL ejecutado en tablet con Windows	Breew	PowerCOBOL (ActiveX, v4 - v11)	2	3 de diciembre de 2016 13:31
[Duda] Leer archivo AcuCobol con PowerCobol	Roger	PowerCOBOL (ActiveX, v4 - v11)	7	28 de septiembre de 2016 10:44

Likes

Likes

Likes

Likes

Likes

Likes

Likes

Likes

Likes

Likes


		Archivo - Cobol Foro		Webdesign by: vbdesigns.de		Contactar con Nosotros - Cobol Foro