Gracias Rui Pinto (Rapinto)
COBOL Foro
Foro dedicado a COBOL, a la Programación y a la Informática.
Retroceder   COBOL Foro > Programación e Informática > Controles y Componentes (DLL/OCX) > Controles y Componentes Gratuitos
Controles y Componentes Gratuitos Componentes Freeware, información y descarga.
Noticias y Avisos
Otros temas que te pueden interesar
Tema Autor Foro Respuestas Último post
[Componente] Factura Electronica Argentina JulioBenitez9470 PowerCOBOL (ActiveX, v4 - v11) 19 26 de abril de 2018 16:17
Respuesta
 
Herramientas

  #1
Antiguo 21 de abril de 2019, 00:10
IDENTIFICATION DIVISION
marcelolarran
Acabo de llegar...
ENVIRONMENT DIVISION
Avatar de marcelolarran
DATA DIVISION
Forero desde (Registrado)octubre 2017
Argentina
UbicaciónCordoba / Rio Cuarto
Edad59 años
Última Actividad20.05.2019 15:34
PROCEDURE DIVISION
PostsPosts: 2
Ha dicho GraciasEnviado: 1
Ha recibido agradecimientosRecibido: 0
Mejores respuestasSoluiones: 0
ReputaciónReputación: 0
marcelolarran is an unknown quantity at this point
Impresora OCX WSAFIPFE facturas electronicas (en Argentina)

Buenas Tardes, esta pregunta es para los que estan usando el OCX WSAFIPFE de Carusso para realizar facturas electronicas (en Argentina), me sucede que en mi powercobol 7 u 9 cualquiera de las 2 versiones
no puedo incorpararlo a la toolbox del formulario, lo visualizo al OCX pero no me deja insertarlo a la barra para despues pasarlo al formulario, les a sucedido esto ? o estoy haciendo algom mal ?, gracias por su colaboracion.
marcelolarran no ha iniciado sesión   Responder Con Cita
  #2
Antiguo 21 de abril de 2019, 15:57
IDENTIFICATION DIVISION
Kuk
Administrador
ENVIRONMENT DIVISION
Avatar de Kuk
DATA DIVISION
Forero desde (Registrado)enero 2015
España
UbicaciónMadrid
Edad34 años
Última Actividad12.12.2019 22:56
PROCEDURE DIVISION
PostsPosts: 1.428
Ha dicho GraciasEnviado: 319
Ha recibido agradecimientosRecibido: 547
Mejores respuestasSoluiones: 87
ReputaciónReputación: 10
Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road
Predeterminado

marcelolarran, qué error te da exactamente? Ojo, a partir de Windows 7 debes ejecutar PowerCOBOL como Administrador, para poder registrar las OCX.


NORMAS DEL FORO - obligatorias de conocer para TODOS.
¿Te han ayudado? NO TE OLVIDES de darle a
¿Quieres dirigirte a alguien en tu post? Notifícale Pinchando en su Nick:

Kuk no ha iniciado sesión   Responder Con Cita
  #3
Antiguo 22 de abril de 2019, 02:31
IDENTIFICATION DIVISION
marcelolarran
Acabo de llegar...
ENVIRONMENT DIVISION
Avatar de marcelolarran
DATA DIVISION
Forero desde (Registrado)octubre 2017
Argentina
UbicaciónCordoba / Rio Cuarto
Edad59 años
Última Actividad20.05.2019 15:34
PROCEDURE DIVISION
PostsPosts: 2
Ha dicho GraciasEnviado: 1
Ha recibido agradecimientosRecibido: 0
Mejores respuestasSoluiones: 0
ReputaciónReputación: 0
marcelolarran is an unknown quantity at this point
Predeterminado

el OCX esta bien instalado, como administrador obviamente, logre incorporarlo a toolbox del formulario, pero cuando ejecuto el propgrama para pedir el CAE me sale el mensaje "Referencia a Objeto no establecida como instancia de un objeto", lei las soluciones al problema, poero no logro darme cuenta porque use el mismo ejemplo que esta en la pagina de CAMUSSO.
marcelolarran no ha iniciado sesión   Responder Con Cita
  #4
Antiguo 22 de abril de 2019, 11:53
IDENTIFICATION DIVISION
Kuk
Administrador
ENVIRONMENT DIVISION
Avatar de Kuk
DATA DIVISION
Forero desde (Registrado)enero 2015
España
UbicaciónMadrid
Edad34 años
Última Actividad12.12.2019 22:56
PROCEDURE DIVISION
PostsPosts: 1.428
Ha dicho GraciasEnviado: 319
Ha recibido agradecimientosRecibido: 547
Mejores respuestasSoluiones: 87
ReputaciónReputación: 10
Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road Kuk is on a distinguished road
Predeterminado

marcelolarran, revisa las dependencias, lo mismo debes tener instalado algún componente más, como por ejemplo alguna versión de C++ Redistributable o similar.


NORMAS DEL FORO - obligatorias de conocer para TODOS.
¿Te han ayudado? NO TE OLVIDES de darle a
¿Quieres dirigirte a alguien en tu post? Notifícale Pinchando en su Nick:

Kuk no ha iniciado sesión   Responder Con Cita
  #5
Antiguo 22 de abril de 2019, 13:46
IDENTIFICATION DIVISION
Gusaiello
Novato Junior
ENVIRONMENT DIVISION
Avatar de Gusaiello
DATA DIVISION
Forero desde (Registrado)febrero 2015
Argentina
UbicaciónQuilmes, Buenos Aires
Edad64 años
Última Actividad12.12.2019 20:22
PROCEDURE DIVISION
PostsPosts: 60
Ha dicho GraciasEnviado: 21
Ha recibido agradecimientosRecibido: 29
Mejores respuestasSoluiones: 2
ReputaciónReputación: 7
Gusaiello is on a distinguished road Gusaiello is on a distinguished road Gusaiello is on a distinguished road
Predeterminado

marcelolarran, Yo tambien tuve problemas con esta ocx, es mas, hablé con el sr. Camusso y vía teamviewer el mismo se metió en mi computadora para ver si encontraba el problema, pero al no tener conocimientos de AcuCobol no logró ayudarme.

La única forma que encontré de poder hacer facturas electrónicas fue a través de la interfase any2fe, la cual funciona como interlocutora entre mi programa y WSAFIPFE. Es mas cara, pero me permitió resolver el problema.

Viene con un instalador el cual se encarga de la instalación de WSAFIPFE, luego con tu programa generas un par de archivitos con los datos de la factura y llamas a any2fe.exe con los parámetros necesarios y asunto resuelto. Solicitaa la autorización y si todo anduvo bien te devuelve el CAE.

Hay otra interfase (PYAFIPWS) que tengo entendido que es gratis, pero bueno, ya había comprado la otra.
Gusaiello no ha iniciado sesión   Responder Con Cita
  #6
Antiguo 10 de mayo de 2019, 14:30
IDENTIFICATION DIVISION
Lascu
Acabo de llegar...
ENVIRONMENT DIVISION
Avatar de Lascu
DATA DIVISION
Forero desde (Registrado)noviembre 2015
Argentina
UbicaciónSanta Fe, Videla
Última Actividad04.12.2019 12:39
PROCEDURE DIVISION
PostsPosts: 25
Ha dicho GraciasEnviado: 28
Ha recibido agradecimientosRecibido: 11
Mejores respuestasSoluiones: 1
ReputaciónReputación: 0
Lascu is on a distinguished road Lascu is on a distinguished road
Predeterminado PyAfipWs

Hola, el PyAfipWs es posible implementarlo gratis. Está escrito en python, en la página (o el foro, ahora no recuerdo) tenés instrucciones paso a paso muy claras de como hacerlo, podés bajar el código fuente y generar el ejecutable. Y si se te complica implementarlo tenés la posibilidad de comprar el soporte técnico por un tiempo.
Saludos

Lascu
Lascu no ha iniciado sesión   Responder Con Cita
Han dicho Gracias: 2
Gusaiello (29 de agosto de 2019), Kuk (10 de mayo de 2019)
  #7
Antiguo 29 de agosto de 2019, 19:17
IDENTIFICATION DIVISION
Gusaiello
Novato Junior
ENVIRONMENT DIVISION
Avatar de Gusaiello
DATA DIVISION
Forero desde (Registrado)febrero 2015
Argentina
UbicaciónQuilmes, Buenos Aires
Edad64 años
Última Actividad12.12.2019 20:22
PROCEDURE DIVISION
PostsPosts: 60
Ha dicho GraciasEnviado: 21
Ha recibido agradecimientosRecibido: 29
Mejores respuestasSoluiones: 2
ReputaciónReputación: 7
Gusaiello is on a distinguished road Gusaiello is on a distinguished road Gusaiello is on a distinguished road
Predeterminado

Lascu, he seguido tu consejo y debo decir que pyafipws funciona de maravilla.

Lo uso mediante el sistema de intercambio a traves de .TXT's.

Es mucho mas veloz que la interfase que venía usando (any2fe - WSAFIPFE).

Pero la mayor de las ventajas es que es gratis y sin licencias.

Hace algunos dias implementé mi primer programa con esta interfase y todo va perfecto.

Desde ya muchas gracias por el consejo.
Gusaiello no ha iniciado sesión   Responder Con Cita
Han dicho Gracias: 2
Kuk (30 de agosto de 2019), Lascu (16 de octubre de 2019)
  #8
Antiguo 31 de agosto de 2019, 15:36
IDENTIFICATION DIVISION
Fito
Novato Senior
ENVIRONMENT DIVISION
Avatar de Fito
DATA DIVISION
Forero desde (Registrado)febrero 2015
Argentina
UbicaciónCórdoba, Villa María
Edad48 años
Última Actividad12.12.2019 00:15
PROCEDURE DIVISION
PostsPosts: 190
Ha dicho GraciasEnviado: 72
Ha recibido agradecimientosRecibido: 55
Mejores respuestasSoluiones: 9
ReputaciónReputación: 10
Fito is on a distinguished road Fito is on a distinguished road Fito is on a distinguished road Fito is on a distinguished road Fito is on a distinguished road Fito is on a distinguished road
Predeterminado

Hola Amigos:

Yo estoy usando esa ocx en power 8, no funciona como otro ocx que se pueda incorporar al formulario. Hay que instanciarlo en tiempo de ejecución. Acá les paso un ejemplo. Funciona de maravilla este ocx.

Código COBOL:
  1.  ENVIRONMENT     DIVISION.
  2.  DATA            DIVISION.
  3.  WORKING-STORAGE SECTION.
  4.  
  5.  77  oFactura                    pic x(8192) value "WSAFIPFE.factura".  
  6.  77  FE object reference OLE.
  7.  01  SRC                         pic x(1024).
  8.  01  MSG                         pic x(1024).
  9.  
  10.  01  ii                          pic 9999.
  11.  
  12.  01  ind                         pic s9(5) comp-5.
  13.  
  14.  01  wcant-reg                   pic s9(9) comp-5.
  15.  01  redefines wcant-reg.
  16.      02 wcant-reg-x              pic x(9).
  17.        
  18. *... variables para usar con ocx
  19.  01  nModoFiscal                 pic s9(4) comp-5.
  20.  01  cCuit                       pic x(11).
  21.  01  redefines cCuit.
  22.      02 cCuit-n                  pic 9(11).
  23.  01  cArchivoCertificado         pic x(50).
  24.  01  cArchivoLicencia            pic x(50).
  25.  
  26.  01  iPuntoVenta                 pic s9(4) comp-5.
  27.  01  iComprobanteTipo            pic s9(4) comp-5.
  28.  01  iComprobanteFor             pic s9(9) comp-5.
  29.  
  30.  01  resultado                   pic x(200).
  31.  
  32.  01  variables-fe.
  33.      02 fe-error               pic s9(9) comp-5.
  34.  
  35.      02 fe-maecuit             pic x(11).
  36.      02 redefines fe-maecuit.
  37.         03 fe-maecuit-n        pic 9(11).
  38.      02 fe-certif              pic x(50).
  39.      02 fe-lic                 pic x(50).
  40.      02 fe-password            pic x(50) value "12345".
  41.      02 fe-valor-n             pic s9(9) comp-5.
  42.      02 fe-valor-c             pic x(25).
  43.      
  44.      02 fe-recibido.
  45.         03                     pic x(6) value "c:\rec".
  46.         03 fe-recibido-suc     pic 9999.
  47.         03                     pic xxxx  value ".xml".
  48.      02 fe-enviado.
  49.         03                     pic x(6) value "c:\env".
  50.         03 fe-enviado-suc      pic 9999.
  51.         03                     pic xxxx  value ".xml".
  52.      
  53.      02 fe-pv                  pic s9(4) comp-5.
  54.      02 fe-tipmov              pic s9(4) comp-5.
  55.      02 fe-concepto            pic s9(4) comp-5.
  56.      02 fe-cuittipo            pic s9(4) comp-5.
  57.      02 fe-cuit                pic x(11).
  58.      02 fe-for                 pic s9(9) comp-5.
  59.      02 fe-fec                 pic x(8).
  60.      02 fe-vto                 pic x(8).
  61.      02 fe-impo                comp-2.
  62.      02 fe-nogavado            comp-2.
  63.      02 fe-neto                comp-2.
  64.      02 fe-iva                 comp-2.
  65.      02 fe-tributos            comp-2.
  66.      02 fe-tributos-id         pic s9(9) comp-5.
  67.      02 fe-86base              comp-2.
  68.      02 fe-86alic              comp-2.
  69.      02 fe-86imp               comp-2.
  70.      02 fe-iibase              comp-2.
  71.      02 fe-iialic              comp-2.
  72.      02 fe-iiimp               comp-2.
  73.      02 fe-Munbase             comp-2.
  74.      02 fe-Munalic             comp-2.
  75.      02 fe-Munimp              comp-2.
  76.  
  77.      02 wrgMun                 pic x(50) value "Tasa Municipal".
  78.      02 wMunbase               pic 9(13)v99.
  79.      02 wMunalic               pic 9(13)v99.
  80.      02 wMunimp                pic 9(13)v99.
  81.  
  82.      02 wrg86                  pic x(50) value "Perc. Ing. Brutos".
  83.      02 w86base                pic 9(13)v99.
  84.      02 w86alic                pic 9(13)v99.
  85.      02 w86imp                 pic 9(13)v99.
  86.  
  87.      02 wimpint                pic x(50) value "Impuestos Internos".
  88.      02 wiibase                pic 9(13)v99.
  89.      02 wiialic                pic 9(13)v99.
  90.      02 wiiimp                 pic 9(13)v99.
  91.  
  92.      02 wtributos              pic 9(13)v99.
  93.      
  94.      02 wneto                  pic 9(13)v99.
  95.      02 wiva                   pic 9(13)v99.
  96.      
  97.      02 fe-indice              pic s9(4) comp-5.
  98.  
  99.      02 fe-cant-iva            pic s9(4) comp-5.
  100.  
  101.      02 fe-tabla-iva occurs 10 times.
  102.         03 fe-iva-id           pic s9(4) comp-5.
  103.         03 fe-iva-base         comp-2.
  104.         03 fe-iva-imp          comp-2.
  105.      
  106.      02 fe-cae                 pic x(20).
  107.      02 fe-caevto              pic x(8).
  108.  
  109.  01  xletra            pic x.
  110.      88 xletra-a       value "A".
  111.      88 xletra-b       value "B".
  112.      88 xletra-c       value "C".
  113.      
  114.  01  muestra.
  115.      02 llite          pic x(20)bb.
  116.      02 limpo          pic zzz.zzz.zzz,zz.
  117.  
  118.  01  muestra2.
  119.      02 llite2         pic x(20)bb.
  120.      02 lnro2          pic z(8).
  121.          
  122.  PROCEDURE       DIVISION.
  123.  
  124.  #include "Copys\declara-com.cpy".
  125.  
  126.  proceso-obtener-cae.
  127.      move spaces                 to ffacae ffacaevto.
  128.  
  129.      move ffanum         to ccnum.
  130.      read ctacte invalid go sale.
  131.  
  132.      if fito-empiva = 1
  133.         if cctipoiva > 2
  134.            move "B"                 to xletra
  135.         else
  136.            move "A"                 to xletra
  137.         end-if
  138.      else
  139.         move "C"                    to xletra
  140.      end-if.  
  141.  
  142.      move ffarestipmov   to tpmcod.
  143.      read tipomov invalid go sale.
  144.  
  145.      move fito-empcuit           to cuit.
  146.      perform resuelve-cuit.
  147.      move ncuit                  to fe-maecuit-n.
  148.      move pfafacelec-cert        to fe-certif.
  149.      move pfafacelec-lic         to fe-lic.
  150.  
  151.      move ffasuc                 to fe-pv fe-recibido-suc fe-enviado-suc.
  152.      move tpmf532-comp           to fe-tipmov.
  153.      move 3                      to fe-concepto.
  154.      move cccuittipo             to fe-cuittipo.
  155.      move cccuit                 to cuit.
  156.      perform resuelve-cuit.
  157.      if ncuit = zeros move 1     to ncuit.
  158.      move ncuit                  to fe-cuit.
  159.  
  160.      move ffafec                 to fecha-inicial.
  161.      move ffavto                 to fecha-final.
  162.      perform fecha-can-dias.
  163.  
  164.      perform fecha-sistema.
  165.      move fecha-amd              to ffafec fe-fec.
  166.  
  167.      move ffafec                 to fecha-inicial.
  168.      perform fecha-suma-dias.
  169.      move fecha-final            to ffavto fe-vto.
  170.  
  171.      move ffaimpo                to fe-impo
  172.      move ffanograv              to fe-nogavado
  173.      if xletra-a
  174.         move ffaneto             to wneto
  175.         move ffaiva              to wiva
  176.      end-if.  
  177.      if xletra-b
  178.         compute wiva  = ffaimpiva(1) + ffaimpiva(2)
  179.         compute wneto = ffaneto - wiva
  180.      end-if.  
  181.      if xletra-c
  182.         move ffaneto             to wneto
  183.         move zeros               to wiva
  184.      end-if.  
  185.      
  186.      move wneto                  to fe-neto.
  187.      
  188.      if fito-empiva = 1
  189.         move wiva                   to fe-iva
  190.         move zeros                  to fe-cant-iva
  191.         perform varying w--ii from 1 by 1 until w--ii > 2
  192.            if ffaimpiva(w--ii) not = zeros
  193.               add 1                 to fe-cant-iva
  194.            end-if
  195.         end-perform
  196.         if fe-cant-iva = 1      *> si hay un solo iva lo hago con el neto por el tema redondeo
  197.            if ffaporiva(1) = 21
  198.               move 5             to fe-iva-id(1)
  199.            else  
  200.               move 4             to fe-iva-id(1)
  201.            end-if  
  202.            if xletra-a
  203.               move ffaneto       to fe-iva-base(1)
  204.               move ffaiva        to fe-iva-imp(1)
  205.            else  
  206.               compute fe-iva-base(1) rounded = ffaneto - ffaimpiva(1)
  207.               move ffaimpiva(1)     to fe-iva-imp(1)
  208.            end-if  
  209.         end-if  
  210.         if fe-cant-iva = 2
  211.            if ffaporiva(1) = 21
  212.               move 5             to fe-iva-id(1)
  213.            else  
  214.               move 4             to fe-iva-id(1)
  215.            end-if  
  216.            compute wneto rounded = ffaimpiva(1) / (ffaporiva(1) / 100)
  217.            move ffaimpiva(1)     to fe-iva-imp(1)
  218.            move wneto            to fe-iva-base(1)
  219.            if ffaporiva(2) = 21
  220.               move 5             to fe-iva-id(2)
  221.            else  
  222.               move 4             to fe-iva-id(2)
  223.            end-if  
  224.            compute wneto rounded = ffaimpiva(2) / (ffaporiva(2) / 100)
  225.            move ffaimpiva(2)     to fe-iva-imp(2)
  226.            move wneto            to fe-iva-base(2)
  227.         end-if  
  228.         if fe-cant-iva = zeros
  229.            move 1                to fe-cant-iva
  230.            move 3                to fe-iva-id(1)
  231.            move ffaneto          to fe-iva-base(1)
  232.            move zeros            to fe-iva-imp(1)
  233.         end-if  
  234.      else
  235.         move zeros               to fe-cant-iva
  236.         move zeros               to fe-iva
  237.      end-if.
  238.      
  239.      move zeros                  to wtributos.
  240.      
  241.      move zeros                  to w86base w86alic w86imp.
  242.      if ffaperiibb-imp not = zeros
  243.         move ffaperiibb-imp      to w86imp
  244.         move ffaperiibb-por      to w86alic
  245.         compute w86base rounded = w86imp * 100 / w86alic
  246.         add  w86imp              to wtributos
  247.      end-if.
  248.      move w86base                to fe-86base.
  249.      move w86alic                to fe-86alic.
  250.      move w86imp                 to fe-86imp.
  251.  
  252.      move zeros                  to wiibase wiialic wiiimp.
  253.      if ffagasoil-itc not = zeros
  254.         add ffagasoil-itc        to wiiimp
  255.         move zeros               to wiialic
  256.         move ffaneto             to wiibase
  257.         add ffagasoil-itc        to wtributos
  258.      end-if.
  259.      if ffagasoil-imp not = zeros
  260.         add ffagasoil-imp        to wiiimp
  261.         move zeros               to wiialic
  262.         move ffaneto             to wiibase
  263.         add ffagasoil-imp        to wtributos
  264.      end-if.
  265.      move wiibase                to fe-iibase.
  266.      move wiialic                to fe-iialic.
  267.      move wiiimp                 to fe-iiimp.
  268.  
  269.      move zeros                  to wMunbase wMunalic wMunimp.
  270.      if ffaimpmuni not = zeros
  271.         move ffaimpmuni          to wMunimp
  272.         move ffapormuni          to wMunalic
  273.         if wMunalic not = zeros
  274.            compute wMunbase rounded = wMunimp * 100 / wMunalic
  275.         else
  276.            move zeros            to wMunbase
  277.         end-if      
  278.         add  wMunimp             to wtributos
  279.      end-if.
  280.      move wMunbase               to fe-Munbase.
  281.      move wMunalic               to fe-Munalic.
  282.      move wMunimp                to fe-Munimp.
  283.  
  284.      move wtributos              to fe-tributos.
  285.      
  286.      if pfafacelec-lic = spaces
  287.         move zeros               to nModoFiscal
  288.      else  
  289.         move 1                   to nModoFiscal
  290.      end-if.  
  291.      move fe-maecuit             to cCuit.
  292.      move fe-certif              to cArchivoCertificado.
  293.      move fe-lic                 to cArchivoLicencia.
  294.      
  295.      if nModoFiscal = zeros
  296.         invoke grdLista "AddItem" using "WebService de PRUEBA"
  297.      else  
  298.         invoke grdLista "AddItem" using "WebService de PRODUCCION"
  299.      end-if.  
  300.      invoke grdLista "AddItem" using cCuit.
  301.      invoke grdLista "AddItem" using cArchivoCertificado.
  302.      invoke grdLista "AddItem" using cArchivoLicencia.
  303.      invoke grdLista "AddItem" using fe-recibido.
  304.      invoke grdLista "AddItem" using fe-enviado.
  305.      perform refresca.
  306.      
  307.      invoke OLE "CREATE-OBJECT" using oFactura returning FE.
  308.      
  309.      invoke FE "iniciar" using nModoFiscal cCuit cArchivoCertificado cArchivoLicencia returning fe-error.
  310.      invoke FE "SET-ArchivoCertificadoPassWord" using fe-password.
  311.      
  312.      if fe-error = pow-true
  313.         perform restaurar-tique
  314.         invoke FE "f1TicketEsValido" returning fe-error
  315.         if fe-error = pow-false
  316.            invoke FE "f1ObtenerTicketAcceso" returning fe-error
  317.            invoke grdLista "AddItem" using "Genera Nuevo Tique"
  318.         else
  319.            invoke grdLista "AddItem" using "El tique es Válido"
  320.         end-if  
  321.         if fe-error = pow-true
  322.            perform guardar-tique
  323.            move fe-pv            to iPuntoVenta
  324.            move fe-tipmov        to iComprobanteTipo
  325.            invoke FE "f1CompUltimoAutorizado" using iPuntoVenta iComprobanteTipo RETURNING iComprobanteFor
  326.            compute fe-for = iComprobanteFor + 1
  327.  
  328.            move "Formulario"     to llite2
  329.            move fe-for           to lnro2
  330.            invoke grdLista "AddItem" using muestra2
  331.  
  332.            move 1                to fe-valor-n
  333.            invoke FE "SET-F1CabeceraCantReg"     using fe-valor-n
  334.            invoke FE "SET-F1CabeceraPtoVta"      using fe-pv  
  335.            invoke FE "SET-F1CabeceraCbteTipo"    using fe-tipmov
  336.            invoke FE "SET-F1DetalleConcepto"     using fe-concepto
  337.            invoke FE "SET-F1DetalleDocTipo"      using fe-cuittipo
  338.            invoke FE "SET-F1DetalleDocNro"       using fe-cuit
  339.            invoke FE "SET-F1DetalleCbteDesde"    using fe-for
  340.            invoke FE "SET-F1DetalleCbteHasta"    using fe-for
  341.            invoke FE "SET-F1DetalleCbteFch"      using fe-fec
  342.            invoke FE "SET-F1DetalleImpTotal"     using fe-impo
  343.            invoke FE "SET-F1DetalleImpTotalConc" using fe-nogavado
  344.            invoke FE "SET-F1DetalleImpNeto"      using fe-neto
  345.            invoke FE "SET-F1DetalleImpIva"       using fe-iva
  346.            invoke FE "SET-F1DetalleImpTrib"      using fe-tributos
  347.  
  348.            invoke FE "SET-F1DetalleFchServDesde" using fe-fec
  349.            invoke FE "SET-F1DetalleFchServHasta" using fe-fec
  350.            invoke FE "SET-F1DetalleFchVtoPago"   using fe-vto
  351.            move "PES"            to fe-valor-c
  352.            invoke FE "SET-F1DetalleMonId"        using fe-valor-c
  353.            move 1                to fe-valor-n
  354.            invoke FE "SET-F1DetalleMonCotiz"     using fe-valor-n
  355.  
  356.            move "Neto"           to llite
  357.            move fe-neto          to limpo
  358.            invoke grdLista "AddItem" using muestra
  359.            move "IVA"            to llite
  360.            move fe-iva           to limpo
  361.            invoke grdLista "AddItem" using muestra
  362.            move "TOTAL"          to llite
  363.            move fe-impo          to limpo
  364.            invoke grdLista "AddItem" using muestra
  365.            perform refresca
  366.      
  367.            move zeros               to w--ii      
  368.            if ffaperiibb-imp not = zeros          
  369.               add 1                 to w--ii
  370.               move w--ii            to fe-valor-n
  371.               invoke FE "SET-F1DetalleTributoItemCantidad" using fe-valor-n
  372.               compute fe-indice = w--ii - 1
  373.               invoke FE "SET-f1IndiceItem"              using fe-indice
  374.               move 2                to fe-tributos-id
  375.               invoke FE "SET-F1DetalleTributoId"        using fe-tributos-id
  376.               invoke FE "SET-F1DetalleTributoDesc"      using wrg86
  377.               invoke FE "SET-F1DetalleTributoBaseImp"   using fe-86base
  378.               invoke FE "SET-F1DetalleTributoAlic"      using fe-86alic
  379.               invoke FE "SET-F1DetalleTributoImporte"   using fe-86imp
  380.               move "PER IIBB Base"  to llite
  381.               move fe-86base        to limpo
  382.               invoke grdLista "AddItem" using muestra
  383.               move "PER IIBB ALic."   to llite
  384.               move fe-86alic        to limpo
  385.               invoke grdLista "AddItem" using muestra
  386.               move "PER IIBB Imp."    to llite
  387.               move fe-86imp         to limpo
  388.               invoke grdLista "AddItem" using muestra
  389.            end-if
  390.            if ffagasoil-itc not = zeros or
  391.               ffagasoil-imp not = zeros
  392.               add 1                 to w--ii
  393.               move w--ii            to fe-valor-n
  394.               invoke FE "SET-F1DetalleTributoItemCantidad" using fe-valor-n
  395.               compute fe-indice = w--ii - 1
  396.               invoke FE "SET-f1IndiceItem"              using fe-indice
  397.               move 4                to fe-tributos-id
  398.               invoke FE "SET-F1DetalleTributoId"        using fe-tributos-id
  399.               invoke FE "SET-F1DetalleTributoDesc"      using wimpint
  400.               invoke FE "SET-F1DetalleTributoBaseImp"   using fe-iibase
  401.               invoke FE "SET-F1DetalleTributoAlic"      using fe-iialic
  402.               invoke FE "SET-F1DetalleTributoImporte"   using fe-iiimp
  403.               move "Imp.Int. Base"  to llite
  404.               move fe-iibase        to limpo
  405.               invoke grdLista "AddItem" using muestra
  406.               move "Imp.Int. ALic." to llite
  407.               move fe-iialic        to limpo
  408.               invoke grdLista "AddItem" using muestra
  409.               move "Imp.Int. Imp."  to llite
  410.               move fe-iiimp         to limpo
  411.               invoke grdLista "AddItem" using muestra
  412.            end-if
  413.            if ffaimpmuni not = zeros          
  414.               add 1                 to w--ii
  415.               move w--ii            to fe-valor-n
  416.               invoke FE "SET-F1DetalleTributoItemCantidad" using fe-valor-n
  417.               move zeros            to fe-indice          
  418.               invoke FE "SET-f1IndiceItem"              using fe-indice
  419.               move 3                to fe-valor-n
  420.               invoke FE "SET-F1DetalleTributoId"        using fe-valor-n
  421.               invoke FE "SET-F1DetalleTributoDesc"      using wrgMun
  422.               invoke FE "SET-F1DetalleTributoBaseImp"   using fe-Munbase
  423.               invoke FE "SET-F1DetalleTributoAlic"      using fe-Munalic
  424.               invoke FE "SET-F1DetalleTributoImporte"   using fe-Munimp
  425.               move "Imp.Mun. Base"  to llite
  426.               move fe-Munbase       to limpo
  427.               invoke grdLista "AddItem" using muestra
  428.               move "Imp.Mun. ALic." to llite
  429.               move fe-Munalic       to limpo
  430.               invoke grdLista "AddItem" using muestra
  431.               move "Imp.Mun. Imp."  to llite
  432.               move fe-Munimp        to limpo
  433.               invoke grdLista "AddItem" using muestra
  434.            end-if
  435.                      
  436.            invoke FE "SET-F1DetalleIvaItemCantidad" using fe-cant-iva
  437.            perform varying w--ii from 1 by 1 until w--ii > fe-cant-iva
  438.               compute fe-indice = w--ii - 1
  439.               invoke FE "SET-f1IndiceItem"        using fe-indice
  440.               invoke FE "SET-F1DetalleIvaId"      using fe-iva-id(w--ii)
  441.               invoke FE "SET-F1DetalleIvaBaseImp" using fe-iva-base(w--ii)
  442.               invoke FE "SET-F1DetalleIvaImporte" using fe-iva-imp(w--ii)
  443.            end-perform
  444.            
  445.            move zeros        to fe-valor-n
  446.            invoke FE "SET-F1DetalleCbtesAsocItemCantidad" using fe-valor-n
  447.            invoke FE "SET-F1DetalleOpcionalItemCantidad"  using fe-valor-n
  448.            
  449.            move fe-recibido  to fe-valor-c
  450.            invoke FE "SET-ArchivoXMLRecibido" using fe-valor-c
  451.            move fe-enviado   to fe-valor-c
  452.            invoke FE "SET-ArchivoXMLEnviado"  using fe-valor-c
  453.  
  454.            invoke FE "f1CAESolicitar"
  455.            
  456.            invoke FE "F1RespuestaResultado" returning Resultado
  457.            if Resultado = "A"
  458.               invoke FE "F1RespuestaDetalleCae" returning Resultado
  459.               move resultado                     to fe-cae
  460.               invoke FE "f1RespuestaDetalleCAEFchVto" returning Resultado
  461.               move resultado                     to fe-caevto
  462.               move fe-for        to ffaresfor
  463.               move fe-cae        to ffacae
  464.               move fe-caevto     to ffacaevto
  465.               move 1             to ffaimpreso
  466.               move fe-fec        to ffafec
  467.               rewrite regffa
  468.               invoke grdLista "AddItem" using "ACEPTADO - CAE N°"
  469.               invoke grdLista "AddItem" using fe-cae
  470.            else  
  471.               invoke grdLista "AddItem" using "RECHAZADO" returning ind
  472.               move pow-color-red        to "ListBackColor"(ind) of grdLista
  473.            end-if  
  474.            invoke FE "f1RespuestaDetalleObservacionItemCantidad" returning fe-error
  475.            if fe-error not = zeros
  476.               perform varying w--ii from 1 by 1 until w--ii > fe-error
  477.                  compute fe-indice = w--ii - 1
  478.                  invoke FE "f1RespuestaDetalleObservacionMsg" returning Resultado
  479.                  invoke grdLista "AddItem" using Resultado returning ind
  480.                  move pow-color-green   to "ListBackColor"(ind) of grdLista
  481.               end-perform
  482.            end-if    
  483.         else
  484.            invoke grdLista "AddItem" using "Fallo Acceso WebService AFIP"
  485.            invoke FE "UltimoMensajeError" returning Resultado
  486.            invoke grdLista "AddItem" using Resultado
  487.         end-if
  488.      else  
  489.         invoke grdLista "AddItem" using "Fallo Iniciando WebService AFIP"
  490.         invoke FE "UltimoMensajeError" returning Resultado
  491.         invoke grdLista "AddItem" using Resultado
  492.      end-if.
  493.  
  494.      perform refresca.
  495.  
  496.  sale.
  497.      exit program.
  498.  
  499.  #include "Copys\comunpro.cpy".
  500.  
  501.  guardar-tique.
  502.      open i-o fe-tique.
  503.      move fe-maecuit-n      to fe-tique-cuit.
  504.      read fe-tique invalid initialize fe-tique-campos.
  505.      invoke FE "f1GuardarTicketAcceso" returning fe-tique-token.
  506.      write regfe-tique invalid rewrite regfe-tique.
  507.      close fe-tique.
  508.  
  509.  restaurar-tique.
  510.      open input fe-tique.
  511.      move fe-maecuit-n      to fe-tique-cuit.
  512.      read fe-tique not invalid
  513.         invoke FE "f1RestaurarTicketAcceso" using fe-tique-token
  514.      end-read.
  515.      close fe-tique.

En el REPOSITORY del formulario tienen que declarar...
Código COBOL:
  1.      CLASS OLE AS "*OLE"
  2.      CLASS EXCEP AS "*COM-EXCEPTION"

Disculpen que le pasé la rutina completa, pero vayan sacando lo que necesitan de ahí...

Saludos.

Fito...
Fito no ha iniciado sesión   Responder Con Cita
Ha dicho Gracias : 1
Lascu (16 de octubre de 2019)
Respuesta


Usuarios activos actualmente viendo este tema: 1 (0 miembros y 1 visitantes)
 
Herramientas

Derechos de Publicación
No puedes publicar nuevos temas
No puedes publicar posts/responder
No puedes adjuntar archivos
No puedes editar tus posts

BB code is habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado



La franja horaria es GMT +1. Ahora son las 11:10.
Powered by: vBulletin, Versión 3.8.7
Derechos de Autor ©2000 - 2019, Jelsoft Enterprises Ltd.