[Sintaxis] Arrastrar y soltar archivos (Drag and Drop)

[Kuk]

@fastpho, sí, efectivamente se me han olvidado las variables en la Working de "MyWndProc", acabo de editar el post original

Me alegro de que te haya funcionado!

P.S. a @Nitzer le va a gustar todo esto

[Kuk]

@fastpho, se me ha ocurrido una manera más elegante de hacerlo.

En "Opened" de tu form pones:

 WORKING-STORAGE SECTION.
 01  imgControl     pic s9(9) comp-5 is external.
 PROCEDURE       DIVISION.
 
     move CmImage1 to imgControl
    

En "MyWndProc" haces esto:

 IDENTIFICATION DIVISION.
 PROGRAM-ID. "MyWndProc". 
 ENVIRONMENT DIVISION.
 CONFIGURATION   SECTION.
 SPECIAL-NAMES.
 REPOSITORY.
     CLASS COM AS "*COM"
     .
 DATA DIVISION.
 WORKING-STORAGE SECTION.  
...
 01  imgControl     pic s9(9) comp-5 is external.
 01  comClass      object reference COM.
...
 
     IF  MSG = WM_DROPFILES         
         call "DragQueryFileA" with stdcall using by value WPARAM
                                                  by value 0
                                                  by reference dropFileName
                                                  by reference fileSize
         
         if  comClass = null
             call "POWERCONVTOCOM" USING imgControl RETURNING comClass
         end-if
         
         invoke comClass "set-ImageName" using dropFileName
     END-IF
          

A ver qué tal, a mi me funciona. Y el código me gusta más, porque el CALL a "XPOW-..." es un poco chapuza.

[HR][/HR]
El ejemplo limpio queda así:

"Opened" del form:

 ENVIRONMENT     DIVISION.
 DATA            DIVISION.
 WORKING-STORAGE SECTION.
 01  wsHwnd         pic s9(9) comp-5.
 01  ptrMyWndProc   procedure-pointer.
 01  newWndProc redefines ptrMyWndProc pic s9(9) comp-5.
 
 01  OldWndProc     is external pic s9(9) comp-5.
 
 01  GWLP-WNDPROC   pic s9(9) comp-5 value -4. 
 
 01  imgControl     pic s9(9) comp-5 is external.
 PROCEDURE       DIVISION.
 
     move CmImage1 to imgControl
         
     set ptrMyWndProc to entry "MyWndProc@16"
     
     move "hwnd" of pow-self to wsHwnd
     
     call "GetWindowLongA" with stdcall using by value wsHwnd
                                              by value GWLP-WNDPROC
                                              returning OldWndProc
                                              
     call "SetWindowLongA" with stdcall using by value wsHwnd
                                              by value GWLP-WNDPROC
                                              by value newWndProc
 
     call "DragAcceptFiles" with stdcall using by value wsHwnd
                                               by value pow-true
                                               
     

"MyWndProc":

 IDENTIFICATION DIVISION.
 PROGRAM-ID. "MyWndProc". 
 ENVIRONMENT DIVISION.
 CONFIGURATION   SECTION.
 SPECIAL-NAMES.
 REPOSITORY.
     CLASS COM AS "*COM"
     .
 DATA DIVISION.
 WORKING-STORAGE SECTION.  
 01  OldWndProc     IS  EXTERNAL PIC S9(9) COMP-5. 
 
 
 01  WM_DROPFILES   PIC  S9(9) COMP-5 VALUE H"0233".  
 
 01  P1                   POINTER.
 01  HWND REDEFINES P1    PIC S9(9) COMP-5.
 01  P2                   POINTER.
 01  MSG  REDEFINES P2    PIC  9(9) COMP-5. 
 01  P3                   POINTER.
 01  WPARAM REDEFINES P3  PIC S9(9) COMP-5.
 01  P4                   POINTER.
 01  LPARAM REDEFINES P4  PIC S9(9) COMP-5. 
 
 01  dropFileName         pic x(250).
 01  fileSize             pic 9(4) comp-5.
 
 01  imgControl     pic s9(9) comp-5 is external.
 01  comClass       object reference COM.
 
 LINKAGE SECTION.
 77  PARM1                PIC S9(9) COMP-5.
 77  PARM2                PIC  9(9) COMP-5. 
 77  PARM3                PIC S9(9) COMP-5.
 77  PARM4                PIC S9(9) COMP-5.
 
 PROCEDURE DIVISION WITH STDCALL USING PARM1 PARM2 PARM3 PARM4. 
     
     MOVE FUNCTION ADDR(PARM1) TO P1
     MOVE FUNCTION ADDR(PARM2) TO P2
     MOVE FUNCTION ADDR(PARM3) TO P3
     MOVE FUNCTION ADDR(PARM4) TO P4
     
     IF  MSG = WM_DROPFILES         
         call "DragQueryFileA" with stdcall using by value WPARAM
                                                  by value 0
                                                  by reference dropFileName
                                                  by reference fileSize
         
         
         if  comClass = null             
             call "POWERCONVTOCOM" USING imgControl RETURNING comClass
         end-if
         
         invoke comClass "set-ImageName" using dropFileName
     END-IF
          
     CALL "CallWindowProcA" WITH STDCALL USING BY VALUE OldWndProc
                                               BY VALUE HWND
                                               BY VALUE MSG
                                               BY VALUE WPARAM
                                               BY VALUE LPARAM  
     
     GOBACK
     .
     

[fastpho]

@Kuk me funciona esta opcion tambien sin usar procedure-pointer, y es mas elegante digamos esta opcion,
lo unico es que tuve que modificar algunas lineas por que en la version 5.0 de PowerCobol para acceder
a objetos se debe usar :

REPOSITORY.
     CLASS OLE AS "*OLE"
     .

y para poder convertir la referencia a la Clase Ole
se debe usar :

 CALL "POWERCONVTOOLE" USING ....

Muchas Gracias por tu tiempo
Saludos

[ATTACH=CONFIG]1010[/ATTACH]

[Kuk]

@fastpho, declarando "OLE" también fucniona en PowerCOBOL v9 y v10.


Lo que no me gusta es que el CmImage de Power no funciona con nada salvo *.JPG y en un formato concreto de JPEG, que los hay diferentes y sigue siendo JPEG pero no los muestra todos. De GIF o PNG ya no digo nada... Es muy pobre este control.

[Kuk]

@fastpho, madre mía el tonto que hemos hecho.........

Acabo de fijarme y CmImage tiene una propiedad llamada DropEnabled, que si la marcas, no hace falta ni WinAPI ni COM/OLE, funciona solito
[ATTACH=CONFIG]1011[/ATTACH]

[fastpho]

@Kuk , si lo probe tildando la opcion DropEnabled y tambien funciona sin la
necesidad de OLE/API , y como decis lo malo del cmimage no toma .png por ejemplo
u otros formatos mas modernos

De todas maneras , DragQueryFileA, sirve por ejemplo para arrastrar archivos en general
a un listview u otro objeto , tiene su sentido todo esto, me parece a parte de arrastrar imagenes.


Saludos...

[Kuk]

@fastpho, sí efectivamente sirve para muchas cosas, pero para el propósito inicial, con un solo clic nos valía

Pero bueno, así hemos aprendido cosas nuevas también

[Fito]

Hola Amigos: ahi estuve probando esto y está espectacular, Felicitaciones.

Ahora una pregunta, esto mismo se puede hacer en RMCobol con WOW?

Saludos

Fito...

[Kuk]

@Fito, yo nunca he tenido RM así que no te puedo decir nada al respecto. Habrá que ir probando y a ver, lo mismo lo hacemos funcionar.

No sé si RM permite llamadas a la WinAPI (o cualquier librería C exterior), si es así, lo más seguro es que lo vamos a poder hacer. Es decir, lo principal, que es el SubClassing de la WinAPI.
Luego lo de invocar algo desde la función, será por OLE u otra cosa, es lo de menos. Encontraremos también la manera de hacerlo.

Te propongo que hagas pruebas, si te salta algún error o no funciona de manera esperada, lo tratamos juntos y vamos viendo
Lo único, si lo hacemos que sea en el apartado de RM, no aquí, para no mezclar las churras con las merinas

[Fito]

Hola Carlitos:

En realidad yo no programo en RM, fue un colega que le mostré esto y como él tiene todo en RM me preguntó y trasladé su inquietud. Te digo más, ni siquiera tengo RM instalado en, mi máquina.

Gracias por responder.

Abrazo...

Fito...